source: trunk/uribl/delist-uri@ 52

#!/usr/bin/perl
# Delist a URI
##
# $Id: delist-uri 41 2012-03-04 20:52:10Z kdeugau $
# Copyright 2010 Kris Deugau <kdeugau@deepnet.cx>
# 
#    This program is free software: you can redistribute it and/or modify
#    it under the terms of the GNU General Public License as published by
#    the Free Software Foundation, either version 3 of the License, or
#    (at your option) any later version. 
# 
#    This program is distributed in the hope that it will be useful,
#    but WITHOUT ANY WARRANTY; without even the implied warranty of
#    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
#    GNU General Public License for more details.
# 
#    You should have received a copy of the GNU General Public License
#    along with this program.  If not, see <http://www.gnu.org/licenses/>.
##

use strict;
use warnings;
use DBI;

use URIdb;

my $uridb = new URIdb;

# default DB info - all other settings should be loaded from the DB.
my $dbhost = "localhost";
my $dbname = "dnsbl";
my $dbuser = "dnsbl";
my $dbpass = "spambgone";

die "Usage: delist-uri <domain>\n"
        if !$ARGV[0];

# Load a config ref containing DB host, name, user, and pass info based on
# from the server name + full script web path.  This allows us to host
# multiple instances without having to duplicate the code.
# This file is a Perl fragment to be processed inline.
if (-e "/etc/uridb/uridb.conf") {
  my $cfg = `cat /etc/uridb/uridb.conf`;
  ($cfg) = ($cfg =~ /^(.+)$/s);         # avoid warnings, failures, and general nastiness with taint mode
  eval $cfg;
}

my $dbh = $uridb->connect($dbhost, $dbname, $dbuser, $dbpass);

my %config;
my $sth = $dbh->prepare("SELECT key,value FROM misc");
$sth->execute;
while (my ($key,$value) = $sth->fetchrow_array) {
  $config{$key} = $value;
}

my $removeme = $ARGV[0];

$sth = $dbh->prepare("SELECT uri,list,count,added,comment FROM urilist WHERE uri=?");
$sth->execute($removeme);
my ($uri,$list,$count,$added,$comment) = $sth->fetchrow_array;

die "URI $removeme not found.  Exiting.\n" if !$uri;

# need to do the next in a single transaction
local $dbh->{AutoCommit} = 0;
local $dbh->{RaiseError} = 1;
eval {
  $sth = $dbh->prepare("INSERT INTO waslisted (uri,list,count,origadded,comment) VALUES (?,?,?,?,?)");
  $sth->execute($uri,$list,$count,$added,$comment);
  $sth = $dbh->prepare("DELETE FROM urilist WHERE uri=?");
  $sth->execute($uri);
  $dbh->commit;
};
if ($@) {
  my $msg = $@;
  eval { $dbh->rollback; };
  print "Failed to move record from urilist to waslisted: $msg\n";
}