source: trunk/cgi-bin/IPDB.pm@ 556

Last change on this file since 556 was 556, checked in by Kris Deugau, 11 years ago

/trunk

Work in progress, see #5:
Update addMaster() to handle new table logic and fields
  • Property svn:keywords set to Date Rev Author
File size: 44.7 KB
Line 
1# ipdb/cgi-bin/IPDB.pm
2# Contains functions for IPDB - database access, subnet mangling, block allocation, etc
3###
4# SVN revision info
5# $Date: 2012-12-18 22:57:27 +0000 (Tue, 18 Dec 2012) $
6# SVN revision $Rev: 556 $
7# Last update by $Author: kdeugau $
8###
9# Copyright (C) 2004-2010 - Kris Deugau
10
11package IPDB;
12
13use strict;
14use warnings;
15use Exporter;
16use DBI;
17use Net::SMTP;
18use NetAddr::IP qw( Compact );
19use POSIX;
20use vars qw($VERSION @ISA @EXPORT @EXPORT_OK %EXPORT_TAGS);
21
22$VERSION = 2; ##VERSION##
23@ISA = qw(Exporter);
24@EXPORT_OK = qw(
25 %disp_alloctypes %list_alloctypes %def_custids @citylist @poplist
26 %IPDBacl %aclmsg
27 &initIPDBGlobals &connectDB &finish &checkDBSanity
28 &addMaster &touchMaster
29 &listSummary &listMaster &listRBlock &listFree &listPool
30 &getMasterList &getTypeList &getPoolSelect &findAllocateFrom
31 &ipParent &subParent &blockParent &getRoutedCity
32 &allocateBlock &updateBlock &deleteBlock &getBlockData
33 &getNodeList &getNodeName &getNodeInfo
34 &mailNotify
35 );
36
37@EXPORT = (); # Export nothing by default.
38%EXPORT_TAGS = ( ALL => [qw(
39 %disp_alloctypes %list_alloctypes %def_custids @citylist @poplist
40 %IPDBacl %aclmsg
41 &initIPDBGlobals &connectDB &finish &checkDBSanity
42 &addMaster &touchMaster
43 &listSummary &listMaster &listRBlock &listFree &listPool
44 &getMasterList &getTypeList &getPoolSelect &findAllocateFrom
45 &ipParent &subParent &blockParent &getRoutedCity
46 &allocateBlock &updateBlock &deleteBlock &getBlockData
47 &getNodeList &getNodeName &getNodeInfo
48 &mailNotify
49 )]
50 );
51
52##
53## Global variables
54##
55our %disp_alloctypes;
56our %list_alloctypes;
57our %def_custids;
58our @citylist;
59our @poplist;
60our %IPDBacl;
61
62# mapping table for functional-area => error message
63our %aclmsg = (
64 addmaster => 'add a master block',
65 addblock => 'add an allocation',
66 updateblock => 'update a block',
67 delblock => 'delete an allocation',
68 );
69
70our $org_name = 'Example Corp';
71our $smtphost = 'smtp.example.com';
72our $domain = 'example.com';
73our $defcustid = '5554242';
74# mostly for rwhois
75##fixme: leave these blank by default?
76our $rwhoisDataPath = '/usr/local/rwhoisd/etc/rwhoisd'; # to match ./configure defaults from rwhoisd-1.5.9.6
77our $org_street = '123 4th Street';
78our $org_city = 'Anytown';
79our $org_prov_state = 'ON';
80our $org_pocode = 'H0H 0H0';
81our $org_country = 'CA';
82our $org_phone = '000-555-1234';
83our $org_techhandle = 'ISP-ARIN-HANDLE';
84our $org_email = 'noc@example.com';
85our $hostmaster = 'dns@example.com';
86
87our $syslog_facility = 'local2';
88
89# Let's initialize the globals.
90## IPDB::initIPDBGlobals()
91# Initialize all globals. Takes a database handle, returns a success or error code
92sub initIPDBGlobals {
93 my $dbh = $_[0];
94 my $sth;
95
96 # Initialize alloctypes hashes
97 $sth = $dbh->prepare("select type,listname,dispname,listorder,def_custid from alloctypes order by listorder");
98 $sth->execute;
99 while (my @data = $sth->fetchrow_array) {
100 $disp_alloctypes{$data[0]} = $data[2];
101 $def_custids{$data[0]} = $data[4];
102 if ($data[3] < 900) {
103 $list_alloctypes{$data[0]} = $data[1];
104 }
105 }
106
107 # City and POP listings
108 $sth = $dbh->prepare("select city,routing from cities order by city");
109 $sth->execute;
110 return (undef,$sth->errstr) if $sth->err;
111 while (my @data = $sth->fetchrow_array) {
112 push @citylist, $data[0];
113 if ($data[1] eq 'y') {
114 push @poplist, $data[0];
115 }
116 }
117
118 # Load ACL data. Specific username checks are done at a different level.
119 $sth = $dbh->prepare("select username,acl from users");
120 $sth->execute;
121 return (undef,$sth->errstr) if $sth->err;
122 while (my @data = $sth->fetchrow_array) {
123 $IPDBacl{$data[0]} = $data[1];
124 }
125
126##fixme: initialize HTML::Template env var for template path
127# something like $self->path().'/templates' ?
128# $ENV{HTML_TEMPLATE_ROOT} = 'foo/bar';
129
130 return (1,"OK");
131} # end initIPDBGlobals
132
133
134## IPDB::connectDB()
135# Creates connection to IPDB.
136# Requires the database name, username, and password.
137# Returns a handle to the db.
138# Set up for a PostgreSQL db; could be any transactional DBMS with the
139# right changes.
140sub connectDB {
141 my $dbname = shift;
142 my $user = shift;
143 my $pass = shift;
144 my $dbhost = shift;
145
146 my $dbh;
147 my $DSN = "DBI:Pg:".($dbhost ? "host=$dbhost;" : '')."dbname=$dbname";
148
149# Note that we want to autocommit by default, and we will turn it off locally as necessary.
150# We may not want to print gobbledygook errors; YMMV. Have to ponder that further.
151 $dbh = DBI->connect($DSN, $user, $pass, {
152 AutoCommit => 1,
153 PrintError => 0
154 })
155 or return (undef, $DBI::errstr) if(!$dbh);
156
157# Return here if we can't select. Note that this indicates a
158# problem executing the select.
159 my $sth = $dbh->prepare("select type from alloctypes");
160 $sth->execute();
161 return (undef,$DBI::errstr) if ($sth->err);
162
163# See if the select returned anything (or null data). This should
164# succeed if the select executed, but...
165 $sth->fetchrow();
166 return (undef,$DBI::errstr) if ($sth->err);
167
168# If we get here, we should be OK.
169 return ($dbh,"DB connection OK");
170} # end connectDB
171
172
173## IPDB::finish()
174# Cleans up after database handles and so on.
175# Requires a database handle
176sub finish {
177 my $dbh = $_[0];
178 $dbh->disconnect if $dbh;
179} # end finish
180
181
182## IPDB::checkDBSanity()
183# Quick check to see if the db is responding. A full integrity
184# check will have to be a separate tool to walk the IP allocation trees.
185sub checkDBSanity {
186 my ($dbh) = $_[0];
187
188 if (!$dbh) {
189 print "No database handle, or connection has been closed.";
190 return -1;
191 } else {
192 # it connects, try a stmt.
193 my $sth = $dbh->prepare("select type from alloctypes");
194 my $err = $sth->execute();
195
196 if ($sth->fetchrow()) {
197 # all is well.
198 return 1;
199 } else {
200 print "Connected to the database, but could not execute test statement. ".$sth->errstr();
201 return -1;
202 }
203 }
204 # Clean up after ourselves.
205# $dbh->disconnect;
206} # end checkDBSanity
207
208
209## IPDB::addMaster()
210# Does all the magic necessary to sucessfully add a master block
211# Requires database handle, block to add
212# Returns failure code and error message or success code and "message"
213sub addMaster {
214 my $dbh = shift;
215 my $cidr = new NetAddr::IP shift;
216
217 # Allow transactions, and raise an exception on errors so we can catch it later.
218 # Use local to make sure these get "reset" properly on exiting this block
219 local $dbh->{AutoCommit} = 0;
220 local $dbh->{RaiseError} = 1;
221
222 # Wrap all the SQL in a transaction
223 eval {
224 my ($mexist) = $dbh->selectrow_array("SELECT cidr FROM masterblocks WHERE cidr <<= ?", undef, ($cidr) );
225
226 if (!$mexist) {
227 # First case - master is brand-spanking-new.
228##fixme: rwhois should be globally-flagable somewhere, much like a number of other things
229## maybe a db table called "config"?
230 $dbh->do("INSERT INTO masterblocks (cidr,rwhois) VALUES (?,?)", undef, ($cidr,'y') );
231
232# Unrouted blocks aren't associated with a city (yet). We don't rely on this
233# elsewhere though; legacy data may have traps and pitfalls in it to break this.
234# Thus the "routed" flag.
235 $dbh->do("INSERT INTO freeblocks (cidr,maskbits,city,routed,parent,rdepth) VALUES (?,?,?,?,?,?)", undef,
236 ($cidr, $cidr->masklen, '<NULL>', 'm', $cidr, 1) );
237
238 # If we get here, everything is happy. Commit changes.
239 $dbh->commit;
240
241 } # done new master does not contain existing master(s)
242 else {
243
244 # collect the master(s) we're going to absorb, and snag the longest netmask while we're at it.
245 my $smallmask = $cidr->masklen;
246 my $sth = $dbh->prepare("SELECT cidr FROM masterblocks WHERE cidr <<= ?");
247 $sth->execute($cidr);
248 my @cmasters;
249 while (my @data = $sth->fetchrow_array) {
250 my $master = new NetAddr::IP $data[0];
251 push @cmasters, $master;
252 $smallmask = $master->masklen if $master->masklen > $smallmask;
253 }
254
255 # split the new master, and keep only those blocks not part of an existing master
256 my @blocklist;
257 foreach my $seg ($cidr->split($smallmask)) {
258 my $contained = 0;
259 foreach my $master (@cmasters) {
260 $contained = 1 if $master->contains($seg);
261 }
262 push @blocklist, $seg if !$contained;
263 }
264
265 # collect the unrouted free blocks within the new master
266 $sth = $dbh->prepare("SELECT cidr FROM freeblocks WHERE masklen(cidr) <= ? AND cidr <<= ? AND routed = 'm'");
267 $sth->execute($smallmask, $cidr);
268 while (my @data = $sth->fetchrow_array) {
269 my $freeblock = new NetAddr::IP $data[0];
270 push @blocklist, $freeblock;
271 }
272
273 # combine the set of free blocks we should have now.
274 @blocklist = Compact(@blocklist);
275
276 # and now insert the new data. Make sure to delete old masters too.
277
278 # freeblocks
279 $sth = $dbh->prepare("DELETE FROM freeblocks WHERE cidr <<= ?");
280 my $sth2 = $dbh->prepare("INSERT INTO freeblocks (cidr,maskbits,city,routed,parent,rdepth)".
281 " VALUES (?,?,'<NULL>','m',?,1)");
282 foreach my $newblock (@blocklist) {
283 $sth->execute($newblock);
284 $sth2->execute($newblock, $newblock->masklen, $cidr);
285 }
286
287 # update parent relations at rdepth=1
288 $dbh->do("UPDATE allocations SET parent = ? WHERE parent << ? AND rdepth=1", undef, ($cidr, $cidr) );
289 $dbh->do("UPDATE freeblocks SET parent = ? WHERE parent << ? AND rdepth=1", undef, ($cidr, $cidr) );
290
291 # master
292 $dbh->do("DELETE FROM masterblocks WHERE cidr <<= ?", undef, ($cidr) );
293 $dbh->do("INSERT INTO masterblocks (cidr,rwhois) VALUES (?,?)", undef, ($cidr, 'y') );
294
295 # *whew* If we got here, we likely suceeded.
296 $dbh->commit;
297 } # new master contained existing master(s)
298 }; # end eval
299
300 if ($@) {
301 my $msg = $@;
302 eval { $dbh->rollback; };
303 return ('FAIL',$msg);
304 } else {
305 return ('OK','OK');
306 }
307} # end addMaster
308
309
310## IPDB::touchMaster()
311# Update last-changed timestamp on a master block.
312sub touchMaster {
313 my $dbh = shift;
314 my $master = shift;
315
316 local $dbh->{AutoCommit} = 0;
317 local $dbh->{RaiseError} = 1;
318
319 eval {
320 $dbh->do("UPDATE masterblocks SET mtime=now() WHERE cidr = ?", undef, ($master));
321 $dbh->commit;
322 };
323
324 if ($@) {
325 my $msg = $@;
326 eval { $dbh->rollback; };
327 return ('FAIL',$msg);
328 }
329 return ('OK','OK');
330} # end touchMaster()
331
332
333## IPDB::listSummary()
334# Get summary list of all master blocks
335# Returns an arrayref to a list of hashrefs containing the master block, routed count,
336# allocated count, free count, and largest free block masklength
337sub listSummary {
338 my $dbh = shift;
339
340 my $mlist = $dbh->selectall_arrayref("SELECT cidr AS master FROM masterblocks ORDER BY cidr", { Slice => {} });
341
342 foreach (@{$mlist}) {
343 my ($rcnt) = $dbh->selectrow_array("SELECT count(*) FROM routed WHERE cidr <<= ?", undef, ($$_{master}));
344 $$_{routed} = $rcnt;
345 my ($acnt) = $dbh->selectrow_array("SELECT count(*) FROM allocations WHERE cidr <<= ?", undef, ($$_{master}));
346 $$_{allocated} = $acnt;
347 my ($fcnt) = $dbh->selectrow_array("SELECT count(*) FROM freeblocks WHERE cidr <<= ?".
348 " AND (routed='y' OR routed='n')", undef, ($$_{master}));
349 $$_{free} = $fcnt;
350 my ($bigfree) = $dbh->selectrow_array("SELECT maskbits FROM freeblocks WHERE cidr <<= ?".
351 " AND (routed='y' OR routed='n') ORDER BY maskbits LIMIT 1", undef, ($$_{master}));
352##fixme: should find a way to do this without having to HTMLize the <>
353 $bigfree = "/$bigfree" if $bigfree;
354 $bigfree = '<NONE>' if !$bigfree;
355 $$_{bigfree} = $bigfree;
356 }
357 return $mlist;
358} # end listSummary()
359
360
361## IPDB::listMaster()
362# Get list of routed blocks in the requested master
363# Returns an arrayref to a list of hashrefs containing the routed block, POP/city the block is routed to,
364# allocated count, free count, and largest free block masklength
365sub listMaster {
366 my $dbh = shift;
367 my $master = shift;
368
369 my $rlist = $dbh->selectall_arrayref("SELECT cidr AS block,city FROM routed WHERE cidr <<= ? ORDER BY cidr",
370 { Slice => {} }, ($master) );
371
372 foreach (@{$rlist}) {
373 my ($acnt) = $dbh->selectrow_array("SELECT count(*) FROM allocations WHERE cidr <<= ?", undef, ($$_{block}));
374 $$_{nsubs} = $acnt;
375 my ($fcnt) = $dbh->selectrow_array("SELECT count(*) FROM freeblocks WHERE cidr <<= ?".
376 " AND (routed='y' OR routed='n')", undef, ($$_{block}));
377 $$_{nfree} = $fcnt;
378 my ($bigfree) = $dbh->selectrow_array("SELECT maskbits FROM freeblocks WHERE cidr <<= ?".
379 " AND (routed='y' OR routed='n') ORDER BY maskbits LIMIT 1", undef, ($$_{block}));
380##fixme: should find a way to do this without having to HTMLize the <>
381 $bigfree = "/$bigfree" if $bigfree;
382 $bigfree = '<NONE>' if !$bigfree;
383 $$_{lfree} = $bigfree;
384 }
385 return $rlist;
386} # end listMaster()
387
388
389## IPDB::listRBlock()
390# Gets a list of free blocks in the requested parent/master in both CIDR and range notation
391# Takes a parent/master and an optional flag to look at routed or unrouted blocks, depending
392# on whether the master is a direct master or a routed block
393# Returns an arrayref to a list of hashrefs containing the CIDR and range-notation blocks
394sub listRBlock {
395 my $dbh = shift;
396 my $routed = shift;
397
398 # Snag the allocations for this block
399 my $sth = $dbh->prepare("SELECT cidr,city,type,custid,swip,description".
400 " FROM allocations WHERE cidr <<= ? ORDER BY cidr");
401 $sth->execute($routed);
402
403 # hack hack hack
404 # set up to flag swip=y records if they don't actually have supporting data in the customers table
405 my $custsth = $dbh->prepare("SELECT count(*) FROM customers WHERE custid = ?");
406
407 my @blocklist;
408 while (my ($cidr,$city,$type,$custid,$swip,$desc) = $sth->fetchrow_array()) {
409 $custsth->execute($custid);
410 my ($ncust) = $custsth->fetchrow_array();
411 my %row = (
412 block => $cidr,
413 city => $city,
414 type => $disp_alloctypes{$type},
415 custid => $custid,
416 swip => ($swip eq 'y' ? 'Yes' : 'No'),
417 partswip => ($swip eq 'y' && $ncust == 0 ? 1 : 0),
418 desc => $desc
419 );
420 $row{subblock} = ($type =~ /^.r$/); # hmf. wonder why these won't work in the hash declaration...
421 $row{listpool} = ($type =~ /^.[pd]$/);
422 push (@blocklist, \%row);
423 }
424 return \@blocklist;
425} # end listRBlock()
426
427
428## IPDB::listFree()
429# Gets a list of free blocks in the requested parent/master in both CIDR and range notation
430# Takes a parent/master and an optional "routed or unrouted" flag that defaults to unrouted.
431# Returns an arrayref to a list of hashrefs containing the CIDR and range-notation blocks
432# Returns some extra flags in the hashrefs for routed blocks, since those can have several subtypes
433sub listFree {
434 my $dbh = shift;
435 my $master = shift;
436 my $routed = shift || 'n';
437
438 # do it this way so we can waste a little less time iterating
439 my $sth = $dbh->prepare("SELECT cidr,routed FROM freeblocks WHERE cidr <<= ? AND ".
440 ($routed eq 'n' ? '' : 'NOT')." routed = 'n' ORDER BY cidr");
441 $sth->execute($master);
442 my @flist;
443 while (my ($cidr,$rtype) = $sth->fetchrow_array()) {
444 $cidr = new NetAddr::IP $cidr;
445 my %row = (
446 fblock => "$cidr",
447 frange => $cidr->range,
448 );
449 if ($routed eq 'y') {
450 $row{subblock} = ($rtype ne 'y' && $rtype ne 'n');
451 $row{fbtype} = $rtype;
452 }
453 push @flist, \%row;
454 }
455 return \@flist;
456} # end listFree()
457
458
459## IPDB::listPool()
460#
461sub listPool {
462 my $dbh = shift;
463 my $pool = shift;
464
465 my $sth = $dbh->prepare("SELECT ip,custid,available,description,type".
466 " FROM poolips WHERE pool = ? ORDER BY ip");
467 $sth->execute($pool);
468 my @poolips;
469 while (my ($ip,$custid,$available,$desc,$type) = $sth->fetchrow_array) {
470 my %row = (
471 ip => $ip,
472 custid => $custid,
473 available => $available,
474 desc => $desc,
475 delme => $available eq 'n'
476 );
477 push @poolips, \%row;
478 }
479 return \@poolips;
480} # end listPool()
481
482
483## IPDB::getMasterList()
484# Get a list of master blocks, optionally including last-modified timestamps
485# Takes an optional flag to indicate whether to include timestamps;
486# 'm' includes ctime, all others (suggest 'c') do not.
487# Returns an arrayref to a list of hashrefs
488sub getMasterList {
489 my $dbh = shift;
490 my $stampme = shift || 'm'; # optional but should be set by caller for clarity
491
492 my $mlist = $dbh->selectall_arrayref("SELECT cidr AS master".($stampme eq 'm' ? ',mtime' : '').
493 " FROM masterblocks ORDER BY cidr", { Slice => {} });
494 return $mlist;
495} # end getMasterList()
496
497
498## IPDB::getTypeList()
499# Get an alloctype/description pair list suitable for dropdowns
500# Takes a flag to determine which general groups of types are returned
501# Returns an reference to an array of hashrefs
502sub getTypeList {
503 my $dbh = shift;
504 my $tgroup = shift || 'a'; # technically optional, like this, but should
505 # really be specified in the call for clarity
506 my $tlist;
507 if ($tgroup eq 'p') {
508 # grouping 'p' - primary allocation types. These include static IP pools (_d and _p),
509 # dynamic-allocation ranges (_e), containers (_c), and the "miscellaneous" cn, in, and en types.
510 $tlist = $dbh->selectall_arrayref("SELECT type,listname FROM alloctypes WHERE listorder < 500 ".
511 "AND type NOT LIKE '_i' AND type NOT LIKE '_r' ORDER BY listorder", { Slice => {} });
512 } elsif ($tgroup eq 'c') {
513 # grouping 'c' - contained types. These include all static IPs and all _r types.
514 $tlist = $dbh->selectall_arrayref("SELECT type,listname FROM alloctypes WHERE listorder <= 500 ".
515 " AND (type LIKE '_i' OR type LIKE '_r') ORDER BY listorder", { Slice => {} });
516 } else {
517 # grouping 'a' - all standard allocation types. This includes everything
518 # but mm (present only as a formality). Make this the default.
519 $tlist = $dbh->selectall_arrayref("SELECT type,listname FROM alloctypes WHERE listorder <= 500 ".
520 " ORDER BY listorder", { Slice => {} });
521 }
522 return $tlist;
523}
524
525
526## IPDB::getPoolSelect()
527# Get a list of pools matching the passed city and type that have 1 or more free IPs
528# Returns an arrayref to a list of hashrefs
529sub getPoolSelect {
530 my $dbh = shift;
531 my $iptype = shift;
532 my $pcity = shift;
533
534 my ($ptype) = ($iptype =~ /^(.)i$/);
535 return if !$ptype;
536 $ptype .= '_';
537
538 my $plist = $dbh->selectall_arrayref(
539 "SELECT (SELECT city FROM allocations WHERE cidr=poolips.pool) AS poolcit, ".
540 "poolips.pool AS poolblock, COUNT(*) AS poolfree FROM poolips,allocations ".
541 "WHERE poolips.available='y' AND poolips.pool=allocations.cidr ".
542 "AND allocations.city = ? AND poolips.type LIKE ? ".
543 "GROUP BY pool", { Slice => {} }, ($pcity, $ptype) );
544 return $plist;
545} # end getPoolSelect()
546
547
548## IPDB::findAllocateFrom()
549# Find free block to add a new allocation from. (CIDR block version of pool select above, more or less)
550# Takes
551# - mask length
552# - allocation type
553# - POP city "parent"
554# - optional master-block restriction
555# - optional flag to allow automatic pick-from-private-network-ranges
556# Returns a string with the first CIDR block matching the criteria, if any
557sub findAllocateFrom {
558 my $dbh = shift;
559 my $maskbits = shift;
560 my $type = shift;
561 my $city = shift;
562 my $pop = shift;
563 my %optargs = @_;
564
565 my $failmsg = "No suitable free block found\n";
566
567## Set up the SQL to find out what freeblock we can (probably) use for an allocation.
568## Very large systems will require development of a reserve system (possibly an extension
569## of the reserve-for-expansion concept in https://secure.deepnet.cx/trac/ipdb/ticket/24?)
570## Also populate a value list for the DBI call.
571
572 my @vallist = ($maskbits, ($type eq 'rm' ? 'n' : ($type =~ /^(.)r$/ ? "$1" : 'y')) );
573 my $sql = "SELECT cidr FROM freeblocks WHERE maskbits <= ? AND routed = ?";
574
575 # for PPP(oE) and container types, the POP city is the one attached to the pool.
576 # individual allocations get listed with the customer city site.
577 ##fixme: chain cities to align roughly with a full layer-2 node graph
578 $city = $pop if $type !~ /^.[pc]$/;
579 if ($type ne 'rm' && $city) {
580 $sql .= " AND city = ?";
581 push @vallist, $city;
582 }
583 # Allow specifying an arbitrary full block, instead of a master
584 if ($optargs{gimme}) {
585 $sql .= " AND cidr >>= ?";
586 push @vallist, $optargs{gimme};
587 }
588 # if a specific master was requested, allow the requestor to self->shoot(foot)
589 if ($optargs{master} && $optargs{master} ne '-') {
590 $sql .= " AND cidr <<= ?" if $optargs{master} ne '-';
591 push @vallist, $optargs{master};
592 } else {
593 # if a specific master was NOT requested, filter out the RFC 1918 private networks
594 if (!$optargs{allowpriv}) {
595 $sql .= " AND NOT (cidr <<= '192.168.0.0/16' OR cidr <<= '10.0.0.0/8' OR cidr <<= '172.16.0.0/12')";
596 }
597 }
598 # Sorting and limiting, since we don't (currently) care to provide a selection of
599 # blocks to carve up. This preserves something resembling optimal usage of the IP
600 # space by forcing contiguous allocations and free blocks as much as possible.
601 $sql .= " ORDER BY maskbits DESC,cidr LIMIT 1";
602
603 my ($fbfound) = $dbh->selectrow_array($sql, undef, @vallist);
604 return $fbfound;
605} # end findAllocateFrom()
606
607
608## IPDB::ipParent()
609# Get an IP's parent pool's details
610# Takes a database handle and IP
611# Returns a hashref to the parent pool block, if any
612sub ipParent {
613 my $dbh = shift;
614 my $block = shift;
615
616 my $pinfo = $dbh->selectrow_hashref("SELECT cidr,custid,type,city,description FROM allocations".
617 " WHERE cidr >>= ?", undef, ($block) );
618 return $pinfo;
619} # end ipParent()
620
621
622## IPDB::subParent()
623# Get a block's parent's details
624# Takes a database handle and CIDR block
625# Returns a hashref to the parent container block, if any
626sub subParent {
627 my $dbh = shift;
628 my $block = shift;
629
630 my $pinfo = $dbh->selectrow_hashref("SELECT cidr,custid,type,city,description FROM allocations".
631 " WHERE cidr >>= ?", undef, ($block) );
632 return $pinfo;
633} # end subParent()
634
635
636## IPDB::blockParent()
637# Get a block's parent's details
638# Takes a database handle and CIDR block
639# Returns a hashref to the parent container block, if any
640sub blockParent {
641 my $dbh = shift;
642 my $block = shift;
643
644 my $pinfo = $dbh->selectrow_hashref("SELECT cidr,city FROM routed".
645 " WHERE cidr >>= ?", undef, ($block) );
646 return $pinfo;
647} # end blockParent()
648
649
650## IPDB::getRoutedCity()
651# Get the city for a routed block.
652sub getRoutedCity {
653 my $dbh = shift;
654 my $block = shift;
655
656 my ($rcity) = $dbh->selectrow_array("SELECT city FROM routed WHERE cidr = ?", undef, ($block) );
657 return $rcity;
658} # end getRoutedCity()
659
660
661## IPDB::allocateBlock()
662# Does all of the magic of actually allocating a netblock
663# Requires a database handle, and a hash containing the block to allocate, routing depth, custid,
664# type, city, block to allocate from, and optionally a description, notes, circuit ID,
665# and private data
666# Returns a success code and optional error message.
667sub allocateBlock {
668 my $dbh = shift;
669
670 my %args = @_;
671
672 $args{cidr} = new NetAddr::IP $args{cidr};
673 $args{alloc_from} = new NetAddr::IP $args{alloc_from};
674
675 $args{desc} = '' if !$args{desc};
676 $args{notes} = '' if !$args{notes};
677 $args{circid} = '' if !$args{circid};
678 $args{privdata} = '' if !$args{privdata};
679 $args{vrf} = '' if !$args{vrf};
680
681 my $sth;
682
683 # Snag the "type" of the freeblock (alloc_from) "just in case"
684 $sth = $dbh->prepare("select routed from freeblocks where cidr='$args{alloc_from}'");
685 $sth->execute;
686 my ($alloc_from_type) = $sth->fetchrow_array;
687
688 # To contain the error message, if any.
689 my $msg = "Unknown error allocating $args{cidr} as '$disp_alloctypes{$args{type}}'";
690
691 # Enable transactions and error handling
692 local $dbh->{AutoCommit} = 0; # These need to be local so we don't
693 local $dbh->{RaiseError} = 1; # step on our toes by accident.
694
695 if ($args{type} =~ /^.i$/) {
696 $msg = "Unable to assign static IP $args{cidr} to $args{custid}";
697 eval {
698 if ($args{cidr}) { # IP specified
699 my ($isavail) = $dbh->selectrow_array("SELECT available FROM poolips WHERE ip=?", undef, ($args{cidr}) );
700 die "IP is not in an IP pool.\n"
701 if !$isavail;
702 die "IP already allocated. Deallocate and reallocate, or update the entry\n"
703 if $isavail eq 'n';
704 } else { # IP not specified, take first available
705 ($args{cidr}) = $dbh->selectrow_array("SELECT ip FROM poolips WHERE pool=? AND available='y' ORDER BY ip",
706 undef, ($args{alloc_from}) );
707 }
708 $dbh->do("UPDATE poolips SET custid=?,city=?,available='n',description=?,notes=?,circuitid=?,privdata=?,vrf=? ".
709 "WHERE ip=?", undef, ($args{custid}, $args{city}, $args{desc}, $args{notes}, $args{circid},
710 $args{privdata}, $args{vrf}, $args{cidr}) );
711
712# node hack
713 if ($args{nodeid} && $args{nodeid} ne '') {
714 $dbh->do("INSERT INTO noderef (block,node_id) VALUES (?,?)", undef, ($args{cidr}, $args{nodeid}) );
715 }
716# end node hack
717
718 $dbh->commit;
719 };
720 if ($@) {
721 $msg .= ": $@";
722 eval { $dbh->rollback; };
723 return ('FAIL',$msg);
724 } else {
725 return ('OK',"$args{cidr}");
726 }
727
728 } else { # end IP-from-pool allocation
729
730 if ($args{cidr} == $args{alloc_from}) {
731 # Easiest case- insert in one table, delete in the other, and go home. More or less.
732 # insert into allocations values (cidr,custid,type,city,desc) and
733 # delete from freeblocks where cidr='cidr'
734 # For data safety on non-transaction DBs, we delete first.
735
736 eval {
737 $msg = "Unable to allocate $args{cidr} as '$disp_alloctypes{$args{type}}'";
738
739 # Get old freeblocks parent/depth/routed for new entries... before we delete it.
740 my ($fparent) = $dbh->selectrow_array("SELECT parent FROM freeblocks WHERE cidr=? AND rdepth=?",
741 undef, ($args{alloc_from}, $args{rdepth}) );
742
743 # Munge freeblocks
744 if ($args{type} =~ /^(.)[mc]$/) {
745 # special case - block is a routed or container/"reserve" block
746 my $rtype = $1;
747 $dbh->do("UPDATE freeblocks SET routed=?,rdepth=rdepth+1,city=?,parent=? WHERE cidr=? AND rdepth=?",
748 undef, ($rtype, $args{city}, $args{cidr}, $args{cidr}, $args{rdepth}));
749 } else {
750 # "normal" case
751 $dbh->do("DELETE FROM freeblocks WHERE cidr=? AND rdepth=?", undef, ($args{cidr}, $args{rdepth}));
752 }
753
754 # Insert the allocations entry
755 $dbh->do("INSERT INTO allocations ".
756 "(cidr,parent,vrf,rdepth,custid,type,city,description,notes,circuitid,privdata)".
757 " VALUES (?,?,?,?,?,?,?,?,?,?,?)", undef,
758 ($args{cidr}, $fparent, $args{vrf}, $args{rdepth}, $args{custid}, $args{type}, $args{city},
759 $args{desc}, $args{notes}, $args{circid}, $args{privdata}) );
760
761 # And initialize the pool, if necessary
762 # PPPoE pools (currently dialup, DSL, and WiFi) get all IPs made available
763 # "DHCP" or "real-subnet" pools have the net, gw, and bcast IPs removed.
764 if ($args{type} =~ /^.p$/) {
765 $msg = "Could not initialize IPs in new $disp_alloctypes{$args{type}} $args{cidr}";
766 my ($code,$rmsg) = initPool($dbh, $args{cidr}, $args{type}, $args{city}, "all");
767 die $rmsg if $code eq 'FAIL';
768 } elsif ($args{type} =~ /^.d$/) {
769 $msg = "Could not initialize IPs in new $disp_alloctypes{$args{type}} $args{cidr}";
770 my ($code,$rmsg) = initPool($dbh, $args{cidr}, $args{type}, $args{city}, "normal");
771 die $rmsg if $code eq 'FAIL';
772 }
773
774# node hack
775 if ($args{nodeid} && $args{nodeid} ne '') {
776 $dbh->do("INSERT INTO noderef (block,node_id) VALUES (?,?)", undef, ($args{cidr}, $args{nodeid}) );
777 }
778# end node hack
779 $dbh->commit;
780 }; # end of eval
781 if ($@) {
782 $msg .= ": ".$@;
783 eval { $dbh->rollback; };
784 return ('FAIL',$msg);
785 } else {
786 return ('OK',"OK");
787 }
788
789 } else { # cidr != alloc_from
790
791 # Hard case. Allocation is smaller than free block.
792 my $wantmaskbits = $args{cidr}->masklen;
793 my $maskbits = $args{alloc_from}->masklen;
794
795 my @newfreeblocks; # Holds free blocks generated from splitting the source freeblock.
796
797 # This determines which blocks will be left "free" after allocation. We take the
798 # block we're allocating from, and split it in half. We see which half the wanted
799 # block is in, and repeat until the wanted block is equal to one of the halves.
800 my $i=0;
801 my $tmp_from = $args{alloc_from}; # So we don't munge $args{alloc_from}
802 while ($maskbits++ < $wantmaskbits) {
803 my @subblocks = $tmp_from->split($maskbits);
804 $newfreeblocks[$i++] = (($args{cidr}->within($subblocks[0])) ? $subblocks[1] : $subblocks[0]);
805 $tmp_from = ( ($args{cidr}->within($subblocks[0])) ? $subblocks[0] : $subblocks[1] );
806 } # while
807
808 # Begin SQL transaction block
809 eval {
810 $msg = "Unable to allocate $args{cidr} as '$disp_alloctypes{$args{type}}'";
811
812 # Get old freeblocks parent/depth/routed for new entries
813 my ($fparent,$fcity,$wasrouted) = $dbh->selectrow_array("SELECT parent,city,routed FROM freeblocks".
814 " WHERE cidr=? AND rdepth=?", undef, ($args{alloc_from}, $args{rdepth}) );
815
816 # Delete old freeblocks entry
817 $dbh->do("DELETE FROM freeblocks WHERE cidr=? AND rdepth=?", undef, ($args{alloc_from}, $args{rdepth}) );
818
819 # Insert new list of smaller free blocks left over
820 $sth = $dbh->prepare("INSERT INTO freeblocks (cidr,city,routed,vrf,parent,rdepth) VALUES (?,?,?,?,?,?)");
821 foreach my $block (@newfreeblocks) {
822 $sth->execute($block, $fcity, $wasrouted, $args{vrf}, $fparent, $args{rdepth});
823 }
824
825 # For routed/container types, add a freeblock within the allocated block so we can subdivide it further
826 if ($args{type} =~ /(.)[mc]/) { # rm and .c types - containers
827 my $rtype = $1;
828 $sth->execute($args{cidr}, $args{city}, $rtype, $args{vrf}, $args{cidr}, $args{rdepth}+1);
829 }
830
831 # Insert the allocations entry
832 $dbh->do("INSERT INTO allocations ".
833 "(cidr,parent,vrf,rdepth,custid,type,city,description,notes,circuitid,privdata)".
834 " VALUES (?,?,?,?,?,?,?,?,?,?,?)", undef,
835 ($args{cidr}, $fparent, $args{vrf}, $args{rdepth}, $args{custid}, $args{type}, $args{city},
836 $args{desc}, $args{notes}, $args{circid}, $args{privdata}) );
837
838 # And initialize the pool, if necessary
839 # PPPoE pools (currently dialup, DSL, and WiFi) get all IPs made available
840 # "DHCP" or "real-subnet" pools have the net, gw, and bcast IPs removed.
841 if ($args{type} =~ /^.p$/) {
842 $msg = "Could not initialize IPs in new $disp_alloctypes{$args{type}} $args{cidr}";
843 my ($code,$rmsg) = initPool($dbh, $args{cidr}, $args{type}, $args{city}, "all");
844 die $rmsg if $code eq 'FAIL';
845 } elsif ($args{type} =~ /^.d$/) {
846 $msg = "Could not initialize IPs in new $disp_alloctypes{$args{type}} $args{cidr}";
847 my ($code,$rmsg) = initPool($dbh, $args{cidr}, $args{type}, $args{city}, "normal");
848 die $rmsg if $code eq 'FAIL';
849 }
850
851# node hack
852 if ($args{nodeid} && $args{nodeid} ne '') {
853 $dbh->do("INSERT INTO noderef (block,node_id) VALUES (?,?)", undef, ($args{cidr}, $args{nodeid}) );
854 }
855# end node hack
856
857 $dbh->commit;
858 }; # end eval
859 if ($@) {
860 $msg .= ": ".$@;
861 eval { $dbh->rollback; };
862 return ('FAIL',$msg);
863 } else {
864 return ('OK',"OK");
865 }
866
867 } # end fullcidr != alloc_from
868
869 } # end static-IP vs netblock allocation
870
871} # end allocateBlock()
872
873
874## IPDB::initPool()
875# Initializes a pool
876# Requires a database handle, the pool CIDR, type, city, and a parameter
877# indicating whether the pool should allow allocation of literally every
878# IP, or if it should reserve network/gateway/broadcast IPs
879# Note that this is NOT done in a transaction, that's why it's a private
880# function and should ONLY EVER get called from allocateBlock()
881sub initPool {
882 my ($dbh,undef,$type,$city,$class) = @_;
883 my $pool = new NetAddr::IP $_[1];
884
885##fixme Need to just replace 2nd char of type with i rather than capturing 1st char of type
886 $type =~ s/[pd]$/i/;
887 my $sth;
888 my $msg;
889
890 # Trap errors so we can pass them back to the caller. Even if the
891 # caller is only ever supposed to be local, and therefore already
892 # trapping errors. >:(
893 local $dbh->{AutoCommit} = 0; # These need to be local so we don't
894 local $dbh->{RaiseError} = 1; # step on our toes by accident.
895
896 eval {
897 # have to insert all pool IPs into poolips table as "unallocated".
898 $sth = $dbh->prepare("insert into poolips (pool,ip,custid,city,type)".
899 " values ('$pool', ?, '$defcustid', ?, '$type')");
900 my @poolip_list = $pool->hostenum;
901 if ($class eq 'all') { # (DSL-ish block - *all* IPs available
902 if ($pool->addr !~ /\.0$/) { # .0 causes weirdness.
903 $sth->execute($pool->addr, $city);
904 }
905 for (my $i=0; $i<=$#poolip_list; $i++) {
906 $sth->execute($poolip_list[$i]->addr, $city);
907 }
908 $pool--;
909 if ($pool->addr !~ /\.255$/) { # .255 can cause weirdness.
910 $sth->execute($pool->addr, $city);
911 }
912 } else { # (real netblock)
913 for (my $i=1; $i<=$#poolip_list; $i++) {
914 $sth->execute($poolip_list[$i]->addr, $city);
915 }
916 }
917 };
918 if ($@) {
919 $msg = $@." '".$sth->errstr."'";
920 eval { $dbh->rollback; };
921 return ('FAIL',$msg);
922 } else {
923 return ('OK',"OK");
924 }
925} # end initPool()
926
927
928## IPDB::updateBlock()
929# Update an allocation
930# Takes all allocation fields in a hash
931sub updateBlock {
932 my $dbh = shift;
933 my %args = @_;
934
935 return ('FAIL', 'Missing block to update') if !$args{block};
936
937 # do it all in a transaction
938 local $dbh->{AutoCommit} = 0;
939 local $dbh->{RaiseError} = 1;
940
941 my @fieldlist;
942 my @vallist;
943 foreach ('custid', 'city', 'description', 'notes', 'circuitid', 'privdata') {
944 if ($args{$_}) {
945 push @fieldlist, $_;
946 push @vallist, $args{$_};
947 }
948 }
949
950 my $updtable = 'allocations';
951 my $keyfield = 'cidr';
952 if ($args{type} =~ /^(.)i$/) {
953 $updtable = 'poolips';
954 $keyfield = 'ip';
955 } else {
956## fixme: there's got to be a better way...
957 if ($args{swip}) {
958 if ($args{swip} eq 'on' || $args{swip} eq '1' || $args{swip} eq 'y') {
959 $args{swip} = 'y';
960 } else {
961 $args{swip} = 'n';
962 }
963 }
964 foreach ('type', 'swip') {
965 if ($args{$_}) {
966 push @fieldlist, $_;
967 push @vallist, $args{$_};
968 }
969 }
970 }
971
972 return ('FAIL', 'No fields to update') if !@fieldlist;
973
974 push @vallist, $args{block};
975 my $sql = "UPDATE $updtable SET ";
976 $sql .= join " = ?, ", @fieldlist;
977 $sql .= " = ? WHERE $keyfield = ?";
978
979 eval {
980 # do the update
981 $dbh->do($sql, undef, @vallist);
982
983 if ($args{node}) {
984 # done with delete/insert so we don't have to worry about funkyness updating a node ref that isn't there
985 $dbh->do("DELETE FROM noderef WHERE block = ?", undef, ($args{block}) );
986 $dbh->do("INSERT INTO noderef (block,node_id) VALUES (?,?)", undef, ($args{block}, $args{node}) );
987 }
988
989 $dbh->commit;
990 };
991 if ($@) {
992 my $msg = $@;
993 $dbh->rollback;
994 return ('FAIL', $msg);
995 }
996 return 0;
997} # end updateBlock()
998
999
1000## IPDB::deleteBlock()
1001# Removes an allocation from the database, including deleting IPs
1002# from poolips and recombining entries in freeblocks if possible
1003# Also handles "deleting" a static IP allocation, and removal of a master
1004# Requires a database handle, the block to delete, and the type of block
1005sub deleteBlock {
1006 my ($dbh,undef,$type) = @_;
1007 my $cidr = new NetAddr::IP $_[1];
1008
1009 my $sth;
1010
1011 # Magic variables used for odd allocation cases.
1012 my $container;
1013 my $con_type;
1014
1015 # To contain the error message, if any.
1016 my $msg = "Unknown error deallocating $type $cidr";
1017 # Enable transactions and exception-on-errors... but only for this sub
1018 local $dbh->{AutoCommit} = 0;
1019 local $dbh->{RaiseError} = 1;
1020
1021 # First case. The "block" is a static IP
1022 # Note that we still need some additional code in the odd case
1023 # of a netblock-aligned contiguous group of static IPs
1024 if ($type =~ /^.i$/) {
1025
1026 eval {
1027 $msg = "Unable to deallocate $disp_alloctypes{$type} $cidr";
1028 $sth = $dbh->prepare("update poolips set custid=?,available='y',".
1029 "city=(select city from allocations where cidr >>= ?".
1030 " order by masklen(cidr) desc limit 1),".
1031 "description='',notes='',circuitid='' where ip=?");
1032 $sth->execute($defcustid, "$cidr", "$cidr");
1033 $dbh->commit;
1034 };
1035 if ($@) {
1036 eval { $dbh->rollback; };
1037 return ('FAIL',$msg);
1038 } else {
1039 return ('OK',"OK");
1040 }
1041
1042 } elsif ($type eq 'mm') { # end alloctype =~ /.i/
1043
1044 $msg = "Unable to delete master block $cidr";
1045 eval {
1046 $sth = $dbh->prepare("delete from masterblocks where cidr='$cidr'");
1047 $sth->execute;
1048 $sth = $dbh->prepare("delete from freeblocks where cidr <<= '$cidr'");
1049 $sth->execute;
1050 $dbh->commit;
1051 };
1052 if ($@) {
1053 eval { $dbh->rollback; };
1054 return ('FAIL', $msg);
1055 } else {
1056 return ('OK',"OK");
1057 }
1058
1059 } else { # end alloctype master block case
1060
1061 ## This is a big block; but it HAS to be done in a chunk. Any removal
1062 ## of a netblock allocation may result in a larger chunk of free
1063 ## contiguous IP space - which may in turn be combined into a single
1064 ## netblock rather than a number of smaller netblocks.
1065
1066 eval {
1067
1068 if ($type eq 'rm') {
1069 $msg = "Unable to remove routing allocation $cidr";
1070 $sth = $dbh->prepare("delete from routed where cidr='$cidr'");
1071 $sth->execute;
1072 # Make sure block getting deleted is properly accounted for.
1073 $sth = $dbh->prepare("update freeblocks set routed='n',city='<NULL>'".
1074 " where cidr='$cidr'");
1075 $sth->execute;
1076 # Set up query to start compacting free blocks.
1077 $sth = $dbh->prepare("select cidr from freeblocks where ".
1078 "maskbits<=".$cidr->masklen." and routed='n' order by maskbits desc");
1079
1080 } else { # end alloctype routing case
1081
1082 # Magic. We need to get information about the containing block (if any)
1083 # so as to make sure that the freeblocks we insert get the correct "type".
1084 $sth = $dbh->prepare("select cidr,type from allocations where cidr >> '$cidr'");
1085 $sth->execute;
1086 ($container, $con_type) = $sth->fetchrow_array;
1087
1088 # Delete all allocations within the block being deleted. This is
1089 # deliberate and correct, and removes the need to special-case
1090 # removal of "container" blocks.
1091 $sth = $dbh->prepare("delete from allocations where cidr <<='$cidr'");
1092 $sth->execute;
1093
1094 # Special case - delete pool IPs
1095 if ($type =~ /^.[pd]$/) {
1096 # We have to delete the IPs from the pool listing.
1097 $sth = $dbh->prepare("delete from poolips where pool='$cidr'");
1098 $sth->execute;
1099 }
1100
1101 # Set up query for compacting free blocks.
1102 if ($con_type && $con_type eq 'pc') {
1103 # Clean up after "bad" allocations (blocks that are not formally
1104 # contained which have nevertheless been allocated from a container block)
1105 # We want to make certain that the freeblocks are properly "labelled"
1106 $sth = $dbh->prepare("select cidr from freeblocks where cidr <<= '$container' order by maskbits desc");
1107 } else {
1108 # Standard deallocation.
1109 $sth = $dbh->prepare("select cidr from freeblocks where cidr <<= ".
1110 "(select cidr from routed where cidr >>= '$cidr') ".
1111 " and maskbits<=".$cidr->masklen.
1112 " and routed='".(($type =~ /^(.)r$/) ? "$1" : 'y').
1113 "' order by maskbits desc");
1114 }
1115
1116 } # end alloctype general case
1117
1118 ## Deallocate legacy blocks stashed in the middle of a static IP pool
1119 ## This may be expandable to an even more general case of contained netblock, or other pool types.
1120
1121 # Find out if the block we're deallocating is within a DSL pool
1122 my $sth2 = $dbh->prepare("SELECT cidr,city,type FROM allocations WHERE type LIKE '_p' AND cidr >>= ?");
1123 $sth2->execute("$cidr");
1124 my ($pool,$poolcity,$pooltype) = $sth2->fetchrow_array;
1125
1126 if ($pool || $sth2->rows) {
1127 # We've already deleted the block, now we have to stuff its IPs into the pool.
1128 $pooltype =~ s/p$/i/; # change type to static IP
1129 $sth2 = $dbh->prepare("INSERT INTO poolips (pool,ip,city,type,custid) values ".
1130 "('$pool',?,'$poolcity','$pooltype','$defcustid')");
1131##fixme: need to not insert net, gateway, and bcast on "real netblock" pools (DHCPish)
1132 # don't insert .0
1133 $sth2->execute($cidr->addr) unless $cidr->addr =~ m|\.0$|;
1134 foreach my $ip ($cidr->hostenum) {
1135 $sth2->execute("$ip");
1136 }
1137 $cidr--;
1138 # don't insert .255
1139 $sth2->execute($cidr->addr) unless $cidr->addr =~ m|\.255$|;
1140 } else { # done returning IPs from a block to a static DSL pool
1141
1142 # Now we look for larger-or-equal-sized free blocks in the same master (routed)
1143 # (super)block. If there aren't any, we can't combine blocks anyway. If there
1144 # are, we check to see if we can combine blocks.
1145 # Execute the statement prepared in the if-else above.
1146
1147 $sth->execute;
1148
1149# NetAddr::IP->compact() attempts to produce the smallest inclusive block
1150# from the caller and the passed terms.
1151# EG: if you call $cidr->compact($ip1,$ip2,$ip3) when $cidr, $ip1, $ip2,
1152# and $ip3 are consecutive /27's starting on .0 (.0-.31, .32-.63,
1153# .64-.95, and .96-.128), you will get an array containing a single
1154# /25 as element 0 (.0-.127). Order is not important; you could have
1155# $cidr=.32/27, $ip1=.96/27, $ip2=.0/27, and $ip3=.64/27.
1156
1157 my (@together, @combinelist);
1158 my $i=0;
1159 while (my @data = $sth->fetchrow_array) {
1160 my $testIP = new NetAddr::IP $data[0];
1161 @together = $testIP->compact($cidr);
1162 my $num = @together;
1163 if ($num == 1) {
1164 $cidr = $together[0];
1165 $combinelist[$i++] = $testIP;
1166 }
1167 }
1168
1169 # Clear old freeblocks entries - if any. They should all be within
1170 # the $cidr determined above.
1171 $sth = $dbh->prepare("delete from freeblocks where cidr <<='$cidr'");
1172 $sth->execute;
1173
1174 # insert "new" freeblocks entry
1175 if ($type eq 'rm') {
1176 $sth = $dbh->prepare("insert into freeblocks (cidr,maskbits,city)".
1177 " values ('$cidr',".$cidr->masklen.",'<NULL>')");
1178 } else {
1179 # Magic hackery to insert "correct" data for deallocation of
1180 # non-contained blocks allocated from within a container.
1181 $type = 'pr' if $con_type && $con_type eq 'pc';
1182
1183 $sth = $dbh->prepare("insert into freeblocks (cidr,maskbits,city,routed)".
1184 " values ('$cidr',".$cidr->masklen.
1185 ",(select city from routed where cidr >>= '$cidr'),'".
1186 (($type =~ /^(.)r$/) ? "$1" : 'y')."')");
1187 }
1188 $sth->execute;
1189
1190 } # done returning IPs to the appropriate place
1191
1192 # If we got here, we've succeeded. Whew!
1193 $dbh->commit;
1194 }; # end eval
1195 if ($@) {
1196 $msg = $@;
1197 eval { $dbh->rollback; };
1198 return ('FAIL', $msg);
1199 } else {
1200 return ('OK',"OK");
1201 }
1202
1203 } # end alloctype != netblock
1204
1205} # end deleteBlock()
1206
1207
1208## IPDB::getBlockData()
1209# Get CIDR or IP, custid, type, city, circuit ID, description, notes, modification time, private/restricted
1210# data, for a CIDR block or pool IP
1211# Also returns SWIP status flag for CIDR blocks
1212# Takes the block/IP to look up
1213# Returns an arrayref to a list of hashrefs
1214sub getBlockData {
1215 my $dbh = shift;
1216 my $block = shift;
1217
1218 my $cidr = new NetAddr::IP $block;
1219
1220 my $keycol = 'cidr';
1221 my $blocktable = 'allocations';
1222 my $poolip = 0;
1223
1224 # Pool IP and IPv6 check all in one! Still needs to be tightened
1225 # up a little for the as-yet-unhandled case of IPv6 IP pools
1226 if ($cidr->bits == 32 && $cidr->masklen == 32) {
1227 $poolip = 1;
1228 $keycol = 'ip';
1229 $blocktable = 'poolips';
1230 }
1231 my $binfo = $dbh->selectrow_hashref("SELECT $keycol AS block, custid, type, city, circuitid, description,".
1232 " notes, modifystamp AS lastmod, privdata".($poolip ? '' : ', swip')." FROM $blocktable".
1233 " WHERE $keycol = ?", undef, ($block) );
1234 return $binfo;
1235} # end getBlockData()
1236
1237
1238## IPDB::getNodeList()
1239# Gets a list of node ID+name pairs as an arrayref to a list of hashrefs
1240sub getNodeList {
1241 my $dbh = shift;
1242
1243 my $ret = $dbh->selectall_arrayref("SELECT node_id, node_name FROM nodes ORDER BY node_type,node_id",
1244 { Slice => {} });
1245 return $ret;
1246} # end getNodeList()
1247
1248
1249## IPDB::getNodeName()
1250# Get node name from the ID
1251sub getNodeName {
1252 my $dbh = shift;
1253 my $nid = shift;
1254
1255 my ($nname) = $dbh->selectrow_array("SELECT node_name FROM nodes WHERE node_id = ?", undef, ($nid) );
1256 return $nname;
1257} # end getNodeName()
1258
1259
1260## IPDB::getNodeInfo()
1261# Get node name and ID associated with a block
1262sub getNodeInfo {
1263 my $dbh = shift;
1264 my $block = shift;
1265
1266 my ($nid, $nname) = $dbh->selectrow_array("SELECT nodes.node_id,node_name FROM nodes INNER JOIN noderef".
1267 " ON nodes.node_id=noderef.node_id WHERE noderef.block = ?", undef, ($block) );
1268 return ($nid, $nname);
1269} # end getNodeInfo()
1270
1271
1272## IPDB::mailNotify()
1273# Sends notification mail to recipients regarding an IPDB operation
1274sub mailNotify {
1275 my $dbh = shift;
1276 my ($action,$subj,$message) = @_;
1277
1278 return if $smtphost eq 'smtp.example.com'; # do nothing if still using default SMTP host.
1279
1280##fixme: need to redesign the breakdown/processing for $action for proper handling of all cases
1281
1282# split action into parts for fiddlement. nb: there are almost certainly better ways to do this.
1283 my @actionbits = split //, $action;
1284
1285 # want to notify anyone who has specifically requested notify on *this* type ($action as passed),
1286 # on "all static IP types" or "all pool types" (and other last-char-in-type groupings), on eg "all DSL types",
1287 # and "all events with this action"
1288 my @actionsets = ($action);
1289##fixme: ick, eww. really gotta find a better way to handle this...
1290 push @actionsets, ($actionbits[0].'.'.$actionbits[2],
1291 $actionbits[0].$actionbits[1].'.', $actionbits[0].'a') if $action =~ /^.{3}$/;
1292
1293 my $mailer = Net::SMTP->new($smtphost, Hello => "ipdb.$domain");
1294
1295 # get recip list from db
1296 my $sth = $dbh->prepare("SELECT reciplist FROM notify WHERE action=?");
1297
1298 my %reciplist;
1299 foreach (@actionsets) {
1300 $sth->execute($_);
1301##fixme - need to handle db errors
1302 my ($recipsub) = $sth->fetchrow_array;
1303 next if !$recipsub;
1304 foreach (split(/,/, $recipsub)) {
1305 $reciplist{$_}++;
1306 }
1307 }
1308
1309 return if !%reciplist;
1310
1311 foreach my $recip (keys %reciplist) {
1312 $mailer->mail("ipdb\@$domain");
1313 $mailer->to($recip);
1314 $mailer->data("From: \"$org_name IP Database\" <ipdb\@$domain>\n",
1315 "To: $recip\n",
1316 "Date: ".strftime("%a, %d %b %Y %H:%M:%S %z",localtime)."\n",
1317 "Subject: {IPDB} $subj\n",
1318 "X-Mailer: IPDB Notify v".sprintf("%.1d",$IPDB::VERSION)."\n",
1319 "Organization: $org_name\n",
1320 "\n$message\n");
1321 }
1322 $mailer->quit;
1323}
1324
1325# Indicates module loaded OK. Required by Perl.
13261;
Note: See TracBrowser for help on using the repository browser.