source: trunk/cgi-bin/main.cgi@ 541

Last change on this file since 541 was 541, checked in by Kris Deugau, 11 years ago

/trunk

Start on SQL in admin.cgi. See #34.

  • Convert Q-n-D allocation list on main page to use existing getTypeList()
  • Convert timestamp-update master block list to use new getMasterList(), with a flag set to return the last-modified time. Also convert main.cgi new assignment page to use this, with the flag set to not return the lastmod.
  • Tweak admin main template to match

While following the code for the master block list, I also removed
several useless globals (@masterblocks, %allocated, %free, and
%routed) since they were only used originally in one place (index
page from main.cgi), obsoleted by changes in r523, and in fact got
overridden locally before that anyway.
  • Property svn:executable set to *
  • Property svn:keywords set to Date Rev Author
File size: 28.6 KB
Line 
1#!/usr/bin/perl
2# ipdb/cgi-bin/main.cgi
3###
4# SVN revision info
5# $Date: 2012-11-02 19:54:31 +0000 (Fri, 02 Nov 2012) $
6# SVN revision $Rev: 541 $
7# Last update by $Author: kdeugau $
8###
9# Copyright (C) 2004-2010 - Kris Deugau
10
11use strict;
12use warnings;
13use CGI::Carp qw(fatalsToBrowser);
14use CGI::Simple;
15use HTML::Template;
16use DBI;
17use POSIX qw(ceil);
18use NetAddr::IP;
19
20use Sys::Syslog;
21
22# don't remove! required for GNU/FHS-ish install from tarball
23##uselib##
24
25use CustIDCK;
26use MyIPDB;
27
28openlog "IPDB","pid","$IPDB::syslog_facility";
29
30## Environment. Collect some things, process some things, set some things...
31
32# Collect the username from HTTP auth. If undefined, we're in
33# a test environment, or called without a username.
34my $authuser;
35if (!defined($ENV{'REMOTE_USER'})) {
36 $authuser = '__temptest';
37} else {
38 $authuser = $ENV{'REMOTE_USER'};
39}
40
41# anyone got a better name? :P
42my $thingroot = $ENV{SCRIPT_FILENAME};
43$thingroot =~ s|cgi-bin/main.cgi||;
44
45syslog "debug", "$authuser active, $ENV{'REMOTE_ADDR'}";
46
47##fixme there *must* be a better order to do things in so this can go back where it was
48# CGI fiddling done here so we can declare %webvar so we can alter $webvar{action}
49# to show the right page on DB errors.
50# Set up the CGI object...
51my $q = new CGI::Simple;
52# ... and get query-string params as well as POST params if necessary
53$q->parse_query_string;
54
55# Convenience; saves changing all references to %webvar
56##fixme: tweak for handling <select multiple='y' size=3> (list with multiple selection)
57my %webvar = $q->Vars;
58
59# Why not a global DB handle? (And a global statement handle, as well...)
60# Use the connectDB function, otherwise we end up confusing ourselves
61my $ip_dbh;
62my $errstr;
63($ip_dbh,$errstr) = connectDB_My;
64if (!$ip_dbh) {
65 $webvar{action} = "dberr";
66} else {
67 initIPDBGlobals($ip_dbh);
68}
69
70# Set up some globals
71$ENV{HTML_TEMPLATE_ROOT} = $thingroot."templates";
72
73my $header = HTML::Template->new(filename => "header.tmpl");
74my $footer = HTML::Template->new(filename => "footer.tmpl");
75
76$header->param(version => $IPDB::VERSION);
77$header->param(addperm => $IPDBacl{$authuser} =~ /a/);
78$header->param(webpath => $IPDB::webpath);
79print "Content-type: text/html\n\n", $header->output;
80
81
82#main()
83my $aclerr;
84
85if(!defined($webvar{action})) {
86 $webvar{action} = "index"; #shuts up the warnings.
87}
88
89my $page;
90if (-e "$ENV{HTML_TEMPLATE_ROOT}/$webvar{action}.tmpl") {
91 $page = HTML::Template->new(filename => "$webvar{action}.tmpl", loop_context_vars => 1);
92} else {
93 $page = HTML::Template->new(filename => "dunno.tmpl");
94}
95
96if($webvar{action} eq 'index') {
97 showSummary();
98} elsif ($webvar{action} eq 'addmaster') {
99 if ($IPDBacl{$authuser} !~ /a/) {
100 $aclerr = 'addmaster';
101 }
102} elsif ($webvar{action} eq 'newmaster') {
103
104 if ($IPDBacl{$authuser} !~ /a/) {
105 $aclerr = 'addmaster';
106 } else {
107 my $cidr = new NetAddr::IP $webvar{cidr};
108 $page->param(cidr => "$cidr");
109
110 my ($code,$msg) = addMaster($ip_dbh, $webvar{cidr});
111
112 if ($code eq 'FAIL') {
113 syslog "err", "Could not add master block '$webvar{cidr}' to database: '$msg'";
114 $page->param(err => $msg);
115 } else {
116 syslog "info", "$authuser added master block $webvar{cidr}";
117 }
118
119 } # ACL check
120
121} # end add new master
122
123elsif($webvar{action} eq 'showmaster') {
124 showMaster();
125}
126elsif($webvar{action} eq 'showrouted') {
127 showRBlock();
128}
129elsif($webvar{action} eq 'listpool') {
130 showPool();
131}
132
133# Not modified or added; just shuffled
134elsif($webvar{action} eq 'assign') {
135 assignBlock();
136}
137elsif($webvar{action} eq 'confirm') {
138 confirmAssign();
139}
140elsif($webvar{action} eq 'insert') {
141 insertAssign();
142}
143elsif($webvar{action} eq 'edit') {
144 edit();
145}
146elsif($webvar{action} eq 'update') {
147 update();
148}
149elsif($webvar{action} eq 'delete') {
150 remove();
151}
152elsif($webvar{action} eq 'finaldelete') {
153 finalDelete();
154}
155elsif ($webvar{action} eq 'nodesearch') {
156 my $nodelist = getNodeList($ip_dbh);
157 $page->param(nodelist => $nodelist);
158}
159
160# DB failure. Can't do much here, really.
161elsif ($webvar{action} eq 'dberr') {
162 $page->param(errmsg => $errstr);
163}
164
165# Default is an error. It shouldn't be possible to get here unless you're
166# randomly feeding in values for webvar{action}.
167else {
168 my $rnd = rand 500;
169 my $boing = sprintf("%.2f", rand 500);
170 my @excuses = (
171 "Aether cloudy. Ask again later about $webvar{action}.",
172 "The gods are unhappy with your sacrificial $webvar{action}.",
173 "Because one of $webvar{action}'s legs are both the same",
174 "<b>wibble</b><br>Can't $webvar{action}, the grue will get me!<br>Can't $webvar{action}, the grue will get me!",
175 "Hey, man, you've had your free $webvar{action}. Next one's gonna... <i>cost</i>....",
176 "I ain't done $webvar{action}",
177 "Oooo, look! A flying $webvar{action}!",
178 "$webvar{action} too evil, avoiding.",
179 "Rocks fall, $webvar{action} dies.",
180 "Bit bucket must be emptied before I can $webvar{action}..."
181 );
182 $page->param(dunno => $excuses[$rnd/50.0]);
183}
184## Finally! Done with that NASTY "case" emulation!
185
186
187# Switch to a different template if we've tripped on an ACL error.
188# Note that this should only be exercised in development, when
189# deeplinked, or when being attacked; normal ACL handling should
190# remove the links a user is not allowed to click on.
191if ($aclerr) {
192 $page = HTML::Template->new(filename => "aclerror.tmpl");
193 $page->param(ipdbfunc => $aclmsg{$aclerr});
194}
195
196# Clean up IPDB globals, DB handle, etc.
197finish($ip_dbh);
198
199## Do all our printing here so we can generate errors and stick them into the slots in the templates.
200
201# can't do this yet, too many blowups
202#print "Content-type: text/html\n\n", $header->output;
203$page->param(webpath => $IPDB::webpath);
204print $page->output;
205
206# include the admin tools link in the output?
207$footer->param(adminlink => ($IPDBacl{$authuser} =~ /A/));
208$footer->param(webpath => $IPDB::webpath);
209print $footer->output;
210
211# Just in case something waaaayyy down isn't in place
212# properly... we exit explicitly.
213exit 0;
214
215
216# Initial display: Show master blocks with total allocated subnets, total free subnets
217sub showSummary {
218 my $masterlist = listSummary($ip_dbh);
219 $page->param(masterlist => $masterlist);
220
221 $page->param(addmaster => ($IPDBacl{$authuser} =~ /a/) );
222} # showSummary
223
224
225# Display detail on master
226# Alrighty then! We're showing routed blocks within a single master this time.
227# We should be able to steal code from showSummary(), and if I'm really smart
228# I'll figger a way to munge the two together. (Once I've done that, everything
229# else should follow. YMMV.)
230sub showMaster {
231
232 $page->param(master => $webvar{block});
233 $page->param(delmaster => ($IPDBacl{$authuser} =~ /d/));
234
235 my $rlist = listMaster($ip_dbh, $webvar{block});
236 $page->param(routedlist => $rlist);
237
238 my $flist = listFree($ip_dbh, $webvar{block});
239 $page->param(unrouted => $flist);
240} # showMaster
241
242
243# Display details of a routed block
244# Alrighty then! We're showing allocations within a routed block this time.
245# We should be able to steal code from showSummary() and showMaster(), and if
246# I'm really smart I'll figger a way to munge all three together. (Once I've
247# done that, everything else should follow. YMMV.
248# This time, we check the database before spewing, because we may
249# not have anything useful to spew.
250sub showRBlock {
251
252 $page->param(master => $webvar{block});
253 $page->param(delrouted => $IPDBacl{$authuser} =~ /d/);
254
255 my $rcity = getRoutedCity($ip_dbh, $webvar{block});
256 $page->param(rcity => $rcity);
257
258 my $blist = listRBlock($ip_dbh, $webvar{block});
259 $page->param(blocklist => $blist);
260
261 my $flist = listFree($ip_dbh, $webvar{block}, 'y');
262 $page->param(unassigned => $flist);
263} # showRBlock
264
265
266# List the IPs used in a pool
267sub showPool {
268
269 my $cidr = new NetAddr::IP $webvar{pool};
270
271 $page->param(block => $webvar{pool});
272 $page->param(netip => $cidr->addr);
273 $cidr++;
274 $page->param(gate => $cidr->addr);
275 $cidr--; $cidr--;
276 $page->param(bcast => $cidr->addr);
277 $page->param(mask => $cidr->mask);
278
279 # Snag pool info for heading
280 my $poolinfo = getBlockData($ip_dbh, $webvar{pool});
281
282 $page->param(disptype => $disp_alloctypes{$poolinfo->{type}});
283 $page->param(city => $poolinfo->{city});
284
285 # Only display net/gw/bcast if it's a "real" netblock and not a PPP(oE) lunacy
286 $page->param(realblock => $poolinfo->{type} =~ /^.d$/);
287
288# probably have to add an "edit IP allocation" link here somewhere.
289
290 my $plist = listPool($ip_dbh, $webvar{pool});
291 # technically slightly more efficient to check the ACL in an if () once outside the foreach
292 foreach (@{$plist}) {
293 $$_{maydel} = $IPDBacl{$authuser} =~ /d/;
294 }
295 $page->param(poolips => $plist);
296} # end showPool
297
298
299# Show "Add new allocation" page. Note that the actual page may
300# be one of two templates, and the lists come from the database.
301sub assignBlock {
302
303 if ($IPDBacl{$authuser} !~ /a/) {
304 $aclerr = 'addblock';
305 return;
306 }
307
308 # hack pthbttt eww
309 $webvar{block} = '' if !$webvar{block};
310
311# hmm. TMPL_IF block and TMPL_ELSE block on these instead?
312 $page->param(rowa => 'row'.($webvar{block} eq '' ? 1 : 0));
313 $page->param(rowb => 'row'.($webvar{block} eq '' ? 0 : 1));
314 $page->param(block => $webvar{block}); # fb-assign flag, if block is set, we're in fb-assign
315 $page->param(iscontained => ($webvar{fbtype} && $webvar{fbtype} ne 'y'));
316
317 # New special case- block to assign is specified
318 if ($webvar{block} ne '') {
319 my $block = new NetAddr::IP $webvar{block};
320
321 # Handle contained freeblock allocation.
322 # This is a little dangerous, as it's *theoretically* possible to
323 # get fbtype='n' (aka a non-routed freeblock). However, should
324 # someone manage to get there, they get what they deserve.
325 if ($webvar{fbtype} ne 'y') {
326 # Snag the type of the container block from the database.
327## hmm. need a flag for parent class/type, sort of?
328 my $pblock = subParent($ip_dbh, $webvar{block});
329 my $ptype = $pblock->{type};
330 $ptype =~ s/c$/r/;
331 $page->param(fbdisptype => $list_alloctypes{$ptype});
332 $page->param(type => $ptype);
333 } else {
334 # get "primary" alloctypes, since these are all that can correctly be assigned if we're in this branch
335 my $tlist = getTypeList($ip_dbh, 'p');
336 $tlist->[0]->{sel} = 1;
337 $page->param(typelist => $tlist);
338 }
339 } else {
340 my $mlist = getMasterList($ip_dbh, 'c');
341 $page->param(masterlist => $mlist);
342
343 my @pops;
344 foreach my $pop (@poplist) {
345 my %row = (pop => $pop);
346 push (@pops, \%row);
347 }
348 $page->param(pops => \@pops);
349
350 # get all standard alloctypes
351 my $tlist = getTypeList($ip_dbh, 'a');
352 $tlist->[0]->{sel} = 1;
353 $page->param(typelist => $tlist);
354 }
355
356 my @cities;
357 foreach my $city (@citylist) {
358 my %row = (city => $city);
359 push (@cities, \%row);
360 }
361 $page->param(citylist => \@cities);
362
363## node hack
364 my $nlist = getNodeList($ip_dbh);
365 $page->param(nodelist => $nlist);
366## end node hack
367
368 $page->param(privdata => $IPDBacl{$authuser} =~ /s/);
369
370} # assignBlock
371
372
373# Take info on requested IP assignment and see what we can provide.
374sub confirmAssign {
375 if ($IPDBacl{$authuser} !~ /a/) {
376 $aclerr = 'addblock';
377 return;
378 }
379
380 my $cidr;
381 my $alloc_from;
382
383 # Going to manually validate some items.
384 # custid and city are automagic.
385 return if !validateInput();
386
387# Several different cases here.
388# Static IP vs netblock
389# + Different flavours of static IP
390# + Different flavours of netblock
391
392 if ($webvar{alloctype} =~ /^.i$/) {
393 my $plist = getPoolSelect($ip_dbh, $webvar{alloctype}, $webvar{pop});
394 $page->param(staticip => 1);
395 $page->param(poollist => $plist) if $plist;
396 $cidr = "Single static IP";
397##fixme: need to handle "no available pools"
398
399 } else { # end show pool options
400
401 if ($webvar{fbassign} && $webvar{fbassign} eq 'y') {
402 $cidr = new NetAddr::IP $webvar{block};
403 $webvar{maskbits} = $cidr->masklen;
404 } else { # done with direct freeblocks assignment
405
406 if (!$webvar{maskbits}) {
407 $page->param(err => "Please specify a CIDR mask length.");
408 return;
409 }
410
411##fixme ick, ew, bleh. gotta handle the failure message generation better. push it into findAllocateFrom()?
412 my $failmsg = "No suitable free block found.<br>\n";
413 if ($webvar{alloctype} eq 'rm') {
414 $failmsg .= "We do not have a free routeable block of that size.<br>\n".
415 "You will have to either route a set of smaller netblocks or a single smaller netblock.";
416 } else {
417 if ($webvar{alloctype} =~ /^.[pc]$/) {
418 $failmsg .= "You will have to route another superblock from one of the<br>\n".
419 "master blocks or chose a smaller block size for the pool.";
420 } else {
421 if (!$webvar{pop}) {
422 $page->param(err => 'Please select a POP to route the block from/through.');
423 return;
424 }
425 $failmsg .= "You will have to route another superblock to $webvar{pop}<br>\n".
426 "from one of the master blocks or chose a smaller blocksize.";
427 }
428 }
429
430 $cidr = findAllocateFrom($ip_dbh, $webvar{maskbits}, $webvar{alloctype}, $webvar{city}, $webvar{pop},
431 (master => $webvar{allocfrom}, allowpriv => $webvar{allowpriv}) );
432 if (!$cidr) {
433 $page->param(err => $failmsg);
434 return;
435 }
436 $cidr = new NetAddr::IP $cidr;
437 } # check for freeblocks assignment or IPDB-controlled assignment
438
439 $alloc_from = "$cidr";
440
441 # If the block to be allocated is smaller than the one we found,
442 # figure out the "real" block to be allocated.
443 if ($cidr->masklen() ne $webvar{maskbits}) {
444 my $maskbits = $cidr->masklen();
445 my @subblocks;
446 while ($maskbits++ < $webvar{maskbits}) {
447 @subblocks = $cidr->split($maskbits);
448 }
449 $cidr = $subblocks[0];
450 }
451 } # if ($webvar{alloctype} =~ /^.i$/)
452
453## node hack
454 if ($webvar{node} && $webvar{node} ne '-') {
455 my $nodename = getNodeName($ip_dbh, $webvar{node});
456 $page->param(nodename => $nodename);
457 $page->param(nodeid => $webvar{node});
458 }
459## end node hack
460
461 # Stick in the allocation data
462 $page->param(alloc_type => $webvar{alloctype});
463 $page->param(typefull => $q->escapeHTML($disp_alloctypes{$webvar{alloctype}}));
464 $page->param(alloc_from => $alloc_from);
465 $page->param(cidr => $cidr);
466 $page->param(city => $q->escapeHTML($webvar{city}));
467 $page->param(custid => $webvar{custid});
468 $page->param(circid => $q->escapeHTML($webvar{circid}));
469 $page->param(desc => $q->escapeHTML($webvar{desc}));
470
471##fixme: find a way to have the displayed copy have <br> substitutions
472# for newlines, and the <input> value have either encoded or bare newlines.
473# Also applies to privdata.
474 $page->param(notes => $q->escapeHTML($webvar{notes},'y'));
475
476 # Check to see if user is allowed to do anything with sensitive data
477 my $privdata = '';
478 $page->param(privdata => $q->escapeHTML($webvar{privdata},'y'))
479 if $IPDBacl{$authuser} =~ /s/;
480
481 # Yay! This now has it's very own little home.
482 $page->param(billinguser => $webvar{userid})
483 if $webvar{userid};
484
485##fixme: this is only needed iff confirm.tmpl and
486# confirmRemove.tmpl are merged (quite possible, just
487# a little tedious)
488 $page->param(action => "insert");
489
490} # end confirmAssign
491
492
493# Do the work of actually inserting a block in the database.
494sub insertAssign {
495 if ($IPDBacl{$authuser} !~ /a/) {
496 $aclerr = 'addblock';
497 return;
498 }
499 # Some things are done more than once.
500 return if !validateInput();
501
502 if (!defined($webvar{privdata})) {
503 $webvar{privdata} = '';
504 }
505 # $code is "success" vs "failure", $msg contains OK for a
506 # successful netblock allocation, the IP allocated for static
507 # IP, or the error message if an error occurred.
508
509 my ($code,$msg) = allocateBlock($ip_dbh, $webvar{fullcidr}, $webvar{alloc_from},
510 $webvar{custid}, $webvar{alloctype}, $webvar{city}, $webvar{desc}, $webvar{notes},
511 $webvar{circid}, $webvar{privdata}, $webvar{node});
512
513 if ($code eq 'OK') {
514 if ($webvar{alloctype} =~ /^.i$/) {
515 $msg =~ s|/32||;
516 $page->param(staticip => $msg);
517 $page->param(custid => $webvar{custid});
518 $page->param(billinguser => $webvar{billinguser});
519 mailNotify($ip_dbh, "a$webvar{alloctype}", "ADDED: $disp_alloctypes{$webvar{alloctype}} allocation",
520 "$disp_alloctypes{$webvar{alloctype}} $msg allocated to customer $webvar{custid}\n".
521 "Description: $webvar{desc}\n\nAllocated by: $authuser\n");
522 } else {
523 my $netblock = new NetAddr::IP $webvar{fullcidr};
524 $page->param(fullcidr => $webvar{fullcidr});
525 $page->param(alloctype => $disp_alloctypes{$webvar{alloctype}});
526 $page->param(custid => $webvar{custid});
527 if ($webvar{alloctype} eq 'pr' && $webvar{billinguser}) {
528 $page->param(billinguser => $webvar{billinguser});
529 $page->param(custid => $webvar{custid});
530 $page->param(netaddr => $netblock->addr);
531 $page->param(masklen => $netblock->masklen);
532 }
533 mailNotify($ip_dbh, "a$webvar{alloctype}", "ADDED: $disp_alloctypes{$webvar{alloctype}} allocation",
534 "$disp_alloctypes{$webvar{alloctype}} $webvar{fullcidr} allocated to customer $webvar{custid}\n".
535 "Description: $webvar{desc}\n\nAllocated by: $authuser\n");
536 }
537 syslog "notice", "$authuser allocated '$webvar{fullcidr}' to '$webvar{custid}' as ".
538 "'$webvar{alloctype}' ($msg)";
539 } else {
540 syslog "err", "Allocation of '$webvar{fullcidr}' to '$webvar{custid}' as ".
541 "'$webvar{alloctype}' by $authuser failed: '$msg'";
542 $page->param(err => "Allocation of $webvar{fullcidr} as '$disp_alloctypes{$webvar{alloctype}}'".
543 " failed:<br>\n$msg\n");
544 }
545
546} # end insertAssign()
547
548
549# Does some basic checks on common input data to make sure nothing
550# *really* weird gets in to the database through this script.
551# Does NOT do complete input validation!!!
552sub validateInput {
553 if ($webvar{city} eq '-') {
554 $page->param(err => 'Please choose a city');
555 return;
556 }
557
558 # Alloctype check.
559 chomp $webvar{alloctype};
560 if (!grep /$webvar{alloctype}/, keys %disp_alloctypes) {
561 # Danger! Danger! alloctype should ALWAYS be set by a dropdown. Anyone
562 # managing to call things in such a way as to cause this deserves a cryptic error.
563 $page->param(err => 'Invalid alloctype');
564 return;
565 }
566
567 # CustID check
568 # We have different handling for customer allocations and "internal" or "our" allocations
569 if ($def_custids{$webvar{alloctype}} eq '') {
570 if (!$webvar{custid}) {
571 $page->param(err => 'Please enter a customer ID.');
572 return;
573 }
574 if ($webvar{custid} !~ /^(?:\d{10}|\d{7}|STAFF)(?:-\d\d?)?$/) {
575 # Force uppercase for now...
576 $webvar{custid} =~ tr/a-z/A-Z/;
577 # Crosscheck with billing.
578 my $status = CustIDCK->custid_exist($webvar{custid});
579 if ($CustIDCK::Error) {
580 $page->param(err => "Error verifying customer ID: ".$CustIDCK::ErrMsg);
581 return;
582 }
583 if (!$status) {
584 $page->param(err => "Customer ID not valid. Make sure the Customer ID ".
585 "is correct.<br>\nUse STAFF for staff static IPs, and $IPDB::defcustid for any other ".
586 "non-customer assignments.");
587 return;
588 }
589 }
590# print "<!-- [ In validateInput(). Insert customer ID cross-check here. ] -->\n";
591 } else {
592 # New! Improved! And now Loaded From The Database!!
593 if ((!$webvar{custid}) || ($webvar{custid} ne 'STAFF')) {
594 $webvar{custid} = $def_custids{$webvar{alloctype}};
595 }
596 }
597
598 # Check POP location
599 my $flag;
600 if ($webvar{alloctype} eq 'rm') {
601 $flag = 'for a routed netblock';
602 foreach (@poplist) {
603 if (/^$webvar{city}$/) {
604 $flag = 'n';
605 last;
606 }
607 }
608 } else {
609 $flag = 'n';
610##fixme: hook to force-set POP or city on certain alloctypes
611# if ($webvar{alloctype =~ /foo,bar,bz/ { $webvar{pop} = 'blah'; }
612 if ($webvar{pop} && $webvar{pop} =~ /^-$/) {
613 $flag = 'to route the block from/through';
614 }
615 }
616
617 # if the alloctype has a restricted city/POP list as determined above,
618 # and the reqested city/POP does not match that list, complain
619 if ($flag ne 'n') {
620 $page->param(err => "Please choose a valid POP location $flag. Valid ".
621 "POP locations are currently:<br>\n".join (" - ", @poplist));
622 return;
623 }
624
625 return 'OK';
626} # end validateInput
627
628
629# Displays details of a specific allocation in a form
630# Allows update/delete
631# action=edit
632sub edit {
633
634 # snag block info from db
635 my $blockinfo = getBlockData($ip_dbh, $webvar{block});
636
637 # Clean up extra whitespace on alloc type. Mainly a legacy-data cleanup.
638 $blockinfo->{type} =~ s/\s//;
639
640 $page->param(block => $webvar{block});
641
642 $page->param(custid => $blockinfo->{custid});
643 $page->param(city => $blockinfo->{city});
644 $page->param(circid => $blockinfo->{circuitid});
645 $page->param(desc => $blockinfo->{description});
646 $page->param(notes => $blockinfo->{notes});
647
648##fixme The check here should be built from the database
649# Need to expand to support pool types too
650 if ($blockinfo->{type} =~ /^.[ne]$/ && $IPDBacl{$authuser} =~ /c/) {
651 $page->param(changetype => 1);
652 $page->param(alloctype => [
653 { selme => ($blockinfo->{type} eq 'me'), type => "me", disptype => "Dialup netblock" },
654 { selme => ($blockinfo->{type} eq 'de'), type => "de", disptype => "Dynamic DSL netblock" },
655 { selme => ($blockinfo->{type} eq 'ce'), type => "ce", disptype => "Dynamic cable netblock" },
656 { selme => ($blockinfo->{type} eq 'we'), type => "we", disptype => "Dynamic wireless netblock" },
657 { selme => ($blockinfo->{type} eq 'cn'), type => "cn", disptype => "Customer netblock" },
658 { selme => ($blockinfo->{type} eq 'en'), type => "en", disptype => "End-use netblock" },
659 { selme => ($blockinfo->{type} eq 'in'), type => "in", disptype => "Internal netblock" },
660 ]
661 );
662 } else {
663 $page->param(disptype => $disp_alloctypes{$blockinfo->{type}});
664 $page->param(type => $blockinfo->{type});
665 }
666
667## node hack
668 my ($nodeid,$nodename) = getNodeInfo($ip_dbh, $webvar{block});
669 $page->param(havenodeid => $nodeid);
670
671 if ($blockinfo->{type} eq 'fr' || $blockinfo->{type} eq 'bi') {
672 $page->param(typesupportsnodes => 1);
673 $page->param(nodename => $nodename);
674
675##fixme: this whole hack needs cleanup and generalization for all alloctypes
676##fixme: arguably a bug that presence of a nodeid implies it can be changed..
677# but except for manual database changes, only the two types fr and bi can
678# (currently) have a nodeid set in the first place.
679 if ($IPDBacl{$authuser} =~ /c/) {
680 my $nlist = getNodeList($ip_dbh);
681 foreach (@{$nlist}) {
682 $$_{selme} = ($$_{node_id} == $nodeid);
683 }
684 $page->param(nodelist => $nlist);
685 }
686 }
687## end node hack
688
689 my ($lastmod,undef) = split /\s+/, $blockinfo->{lastmod};
690 $page->param(lastmod => $lastmod);
691
692 # not happy with the upside-down logic, but...
693 $page->param(swipable => $blockinfo->{type} !~ /.i/);
694 $page->param(swip => $blockinfo->{swip} ne 'n') if $blockinfo->{swip};
695
696 # Check to see if we can display sensitive data
697 $page->param(nocling => $IPDBacl{$authuser} =~ /s/);
698 $page->param(privdata => $blockinfo->{privdata});
699
700 # ACL trickery - these two template booleans control the presence of all form/input tags
701 $page->param(maychange => $IPDBacl{$authuser} =~ /c/);
702 $page->param(maydel => $IPDBacl{$authuser} =~ /d/);
703
704} # edit()
705
706
707# Stuff new info about a block into the db
708# action=update
709sub update {
710 if ($IPDBacl{$authuser} !~ /c/) {
711 $aclerr = 'updateblock';
712 return;
713 }
714
715 # Make sure incoming data is in correct format - custID among other things.
716 return if !validateInput;
717
718 $webvar{swip} = 'n' if !$webvar{swip};
719
720 my %updargs = (
721 custid => $webvar{custid},
722 city => $webvar{city},
723 description => $webvar{desc},
724 notes => $webvar{notes},
725 circuitid => $webvar{circid},
726 block => $webvar{block},
727 type => $webvar{alloctype},
728 swip => $webvar{swip},
729 );
730
731 # Semioptional values
732 $updargs{privdata} = $webvar{privdata} if $IPDBacl{$authuser} =~ /s/;
733 $updargs{node} = $webvar{node} if $webvar{node};
734
735 my ($code,$msg) = updateBlock($ip_dbh, %updargs);
736
737 if ($code eq 'FAIL') {
738 syslog "err", "$authuser could not update block/IP '$webvar{block}': '$msg'";
739 $page->param(err => "Could not update block/IP $webvar{block}: $msg");
740 return;
741 }
742
743 # If we get here, the operation succeeded.
744 syslog "notice", "$authuser updated $webvar{block}";
745##fixme: log details of the change? old way is in the .debug stream anyway.
746##fixme: need to wedge something in to allow "update:field" notifications
747## hmm. how to tell what changed? O_o
748mailNotify($ip_dbh, 's:swi', "SWIPed: $disp_alloctypes{$webvar{alloctype}} $webvar{block}",
749 "$webvar{block} had SWIP status changed to \"Yes\" by $authuser") if $webvar{swip} eq 'on';
750
751## node hack
752 if ($webvar{node} && $webvar{node} ne '-') {
753 my $nodename = getNodeName($ip_dbh, $webvar{node});
754 $page->param(nodename => $nodename);
755 }
756## end node hack
757
758 # Link back to browse-routed or list-pool page on "Update complete" page.
759 my $cblock;
760 if (my $pooltype = ($webvar{alloctype} =~ /^(.)i$/) ) {
761 $page->param(backpool => 1);
762 $cblock = ipParent($ip_dbh, $webvar{block});
763 } else {
764 $cblock = blockParent($ip_dbh, $webvar{block});
765 }
766 $page->param(backblock => $cblock->{cidr});
767
768 # Do some HTML fiddling here instead of using ESCAPE=HTML in the template,
769 # because otherwise we can't convert \n to <br>. *sigh*
770 $webvar{notes} = $q->escapeHTML($webvar{notes}); # escape first...
771 $webvar{notes} =~ s/\n/<br>\n/; # ... then convert newlines
772 $webvar{privdata} = ($webvar{privdata} ? $q->escapeHTML($webvar{privdata}) : "&nbsp;");
773 $webvar{privdata} =~ s/\n/<br>\n/;
774
775 $page->param(cidr => $webvar{block});
776 $page->param(city => $webvar{city});
777 $page->param(disptype => $disp_alloctypes{$webvar{alloctype}});
778 $page->param(custid => $webvar{custid});
779 $page->param(swip => $webvar{swip} eq 'on' ? 'Yes' : 'No');
780 $page->param(circid => $webvar{circid});
781 $page->param(desc => $webvar{desc});
782 $page->param(notes => $webvar{notes});
783 $page->param(privdata => $webvar{privdata})
784 if $IPDBacl{$authuser} =~ /s/;
785
786} # update()
787
788
789# Delete an allocation.
790sub remove {
791 if ($IPDBacl{$authuser} !~ /d/) {
792 $aclerr = 'delblock';
793 return;
794 }
795
796 # Serves'em right for getting here...
797 if (!defined($webvar{block})) {
798 $page->param(err => "Can't delete a block that doesn't exist");
799 return;
800 }
801
802 my $blockdata;
803
804 if ($webvar{alloctype} eq 'rm') {
805
806 $blockdata->{block} = $webvar{block};
807 $blockdata->{city} = getRoutedCity($ip_dbh, $webvar{block});
808 $blockdata->{custid} = "N/A";
809 $blockdata->{type} = $webvar{alloctype};
810 $blockdata->{circuitid} = "N/A";
811 $blockdata->{description} = "N/A";
812 $blockdata->{notes} = "N/A";
813 $blockdata->{privdata} = "N/A";
814
815 } elsif ($webvar{alloctype} eq 'mm') {
816
817 $blockdata->{block} = $webvar{block};
818 $blockdata->{city} = "N/A";
819 $blockdata->{custid} = "N/A";
820 $blockdata->{type} = $webvar{alloctype};
821 $blockdata->{circuitid} = "N/A";
822 $blockdata->{description} = "N/A";
823 $blockdata->{notes} = "N/A";
824 $blockdata->{privdata} = "N/A";
825
826 } else {
827
828 $blockdata = getBlockData($ip_dbh, $webvar{block})
829
830 } # end cases for different alloctypes
831
832 $page->param(block => $blockdata->{block});
833 $page->param(disptype => $disp_alloctypes{$blockdata->{type}});
834 $page->param(type => $blockdata->{type});
835 $page->param(city => $blockdata->{city});
836 $page->param(custid => $blockdata->{custid});
837 $page->param(circid => $blockdata->{circuitid});
838 $page->param(desc => $blockdata->{description});
839 $blockdata->{notes} = $q->escapeHTML($blockdata->{notes});
840 $blockdata->{notes} =~ s/\n/<br>\n/;
841 $page->param(notes => $blockdata->{notes});
842 $blockdata->{privdata} = $q->escapeHTML($blockdata->{privdata});
843 $blockdata->{privdata} = '&nbsp;' if !$blockdata->{privdata};
844 $blockdata->{privdata} =~ s/\n/<br>\n/;
845 $page->param(privdata => $blockdata->{privdata}) if $IPDBacl{$authuser} =~ /s/;
846 $page->param(delpool => $blockdata->{type} =~ /^.[pd]$/);
847
848} # end remove()
849
850
851# Delete an allocation. Return it to the freeblocks table; munge
852# data as necessary to keep as few records as possible in freeblocks
853# to prevent weirdness when allocating blocks later.
854# Remove IPs from pool listing if necessary
855sub finalDelete {
856 if ($IPDBacl{$authuser} !~ /d/) {
857 $aclerr = 'delblock';
858 return;
859 }
860
861 # need to retrieve block data before deleting so we can notify on that
862 my $blockinfo = getBlockData($ip_dbh, $webvar{block});
863
864 my ($code,$msg) = deleteBlock($ip_dbh, $webvar{block}, $webvar{alloctype});
865
866 $page->param(block => $webvar{block});
867 if ($code eq 'OK') {
868 syslog "notice", "$authuser deallocated '$webvar{alloctype}'-type netblock $webvar{block} ".
869 $blockinfo->{custid}.", ".$blockinfo->{city}.", desc='".$blockinfo->{description}."'";
870 mailNotify($ip_dbh, 'da', "REMOVED: $disp_alloctypes{$webvar{alloctype}} $webvar{block}",
871 "$disp_alloctypes{$webvar{alloctype}} $webvar{block} deallocated by $authuser\n".
872 "CustID: ".$blockinfo->{custid}."\nCity: ".$blockinfo->{city}.
873 "\nDescription: ".$blockinfo->{description}."\n");
874 } else {
875 $page->param(failmsg => $msg);
876 if ($webvar{alloctype} =~ /^.i$/) {
877 syslog "err", "$authuser could not deallocate static IP '$webvar{block}': '$msg'";
878 } else {
879 syslog "err", "$authuser could not deallocate netblock '$webvar{block}': '$msg'";
880 $page->param(netblock => 1);
881 }
882 }
883
884} # finalDelete
Note: See TracBrowser for help on using the repository browser.