source: trunk/cgi-bin/main.cgi@ 692

Last change on this file since 692 was 692, checked in by Kris Deugau, 10 years ago

/trunk

Start adding support for advisory "reserved block" assignments - when
creating a new assignment, flag an equal-sized block ahead or behind
to expand the assignment in the future. See #24.

  • free block assignment
  • guided assignment (still needs tweaking to dodge existing reserved blocks)
  • note flagged blocks in free block list
  • Property svn:executable set to *
  • Property svn:keywords set to Date Rev Author
File size: 38.1 KB
Line 
1#!/usr/bin/perl
2# ipdb/cgi-bin/main.cgi
3###
4# SVN revision info
5# $Date: 2015-02-11 23:43:22 +0000 (Wed, 11 Feb 2015) $
6# SVN revision $Rev: 692 $
7# Last update by $Author: kdeugau $
8###
9# Copyright (C) 2004-2010 - Kris Deugau
10
11use strict;
12use warnings;
13use CGI::Carp qw(fatalsToBrowser);
14use CGI::Simple;
15use HTML::Template;
16use DBI;
17use POSIX qw(ceil);
18use NetAddr::IP;
19use Frontier::Client;
20
21use Sys::Syslog;
22
23# don't remove! required for GNU/FHS-ish install from tarball
24##uselib##
25
26use CustIDCK;
27use MyIPDB;
28
29openlog "IPDB","pid","$IPDB::syslog_facility";
30
31## Environment. Collect some things, process some things, set some things...
32
33# Collect the username from HTTP auth. If undefined, we're in
34# a test environment, or called without a username.
35my $authuser;
36if (!defined($ENV{'REMOTE_USER'})) {
37 $authuser = '__temptest';
38} else {
39 $authuser = $ENV{'REMOTE_USER'};
40}
41
42# anyone got a better name? :P
43my $thingroot = $ENV{SCRIPT_FILENAME};
44$thingroot =~ s|cgi-bin/main.cgi||;
45
46syslog "debug", "$authuser active, $ENV{'REMOTE_ADDR'}";
47
48##fixme there *must* be a better order to do things in so this can go back where it was
49# CGI fiddling done here so we can declare %webvar so we can alter $webvar{action}
50# to show the right page on DB errors.
51# Set up the CGI object...
52my $q = new CGI::Simple;
53# ... and get query-string params as well as POST params if necessary
54$q->parse_query_string;
55
56# Convenience; saves changing all references to %webvar
57##fixme: tweak for handling <select multiple='y' size=3> (list with multiple selection)
58my %webvar = $q->Vars;
59
60# Why not a global DB handle? (And a global statement handle, as well...)
61# Use the connectDB function, otherwise we end up confusing ourselves
62my $ip_dbh;
63my $errstr;
64($ip_dbh,$errstr) = connectDB_My;
65if (!$ip_dbh) {
66 $webvar{action} = "dberr";
67} else {
68 initIPDBGlobals($ip_dbh);
69}
70
71# Set up some globals
72$ENV{HTML_TEMPLATE_ROOT} = $thingroot."templates";
73
74my $header = HTML::Template->new(filename => "header.tmpl");
75my $footer = HTML::Template->new(filename => "footer.tmpl");
76
77$header->param(version => $IPDB::VERSION);
78$header->param(addperm => $IPDBacl{$authuser} =~ /a/);
79$header->param(webpath => $IPDB::webpath);
80print "Content-type: text/html\n\n", $header->output;
81
82
83#main()
84my $aclerr;
85
86if(!defined($webvar{action})) {
87 $webvar{action} = "index"; #shuts up the warnings.
88}
89
90my $page;
91if (-e "$ENV{HTML_TEMPLATE_ROOT}/$webvar{action}.tmpl") {
92 $page = HTML::Template->new(filename => "$webvar{action}.tmpl", loop_context_vars => 1, global_vars => 1);
93} else {
94 $page = HTML::Template->new(filename => "dunno.tmpl");
95}
96
97if($webvar{action} eq 'index') {
98 showSummary();
99} elsif ($webvar{action} eq 'addmaster') {
100 if ($IPDBacl{$authuser} !~ /a/) {
101 $aclerr = 'addmaster';
102 }
103
104 # Retrieve the list of DNS locations if we've got a place to grab them from
105 if ($IPDB::rpc_url) {
106
107 my %rpcargs = (
108 rpcuser => $authuser,
109 group => 1, # bleh
110 defloc => '',
111 );
112 my $result = IPDB::_rpc('getLocDropdown', %rpcargs);
113 $page->param(loclist => $result);
114 }
115
116} elsif ($webvar{action} eq 'newmaster') {
117
118 if ($IPDBacl{$authuser} !~ /a/) {
119 $aclerr = 'addmaster';
120 } else {
121 my $cidr = new NetAddr::IP $webvar{cidr};
122 $page->param(cidr => "$cidr");
123
124 my ($code,$msg) = addMaster($ip_dbh, $webvar{cidr}, (vrf => $webvar{vrf}, rdns => $webvar{rdns},
125 rwhois => $webvar{rwhois}, defloc => $webvar{loc}, user => $authuser) );
126
127 if ($code eq 'FAIL') {
128 syslog "err", "Could not add master block '$webvar{cidr}' to database: '$msg'";
129 $page->param(err => $msg);
130 } else {
131 $page->param(parent => $msg);
132 if ($code eq 'WARN') {
133 $IPDB::errstr =~ s/\n\n/<br>\n/g;
134 $IPDB::errstr =~ s/:\n/:<br>\n/g;
135 $page->param(warn => $IPDB::errstr);
136 }
137 syslog "info", "$authuser added master block $webvar{cidr}";
138 }
139
140 } # ACL check
141
142} # end add new master
143
144elsif ($webvar{action} eq 'showsubs') {
145 showSubs();
146}
147
148elsif($webvar{action} eq 'listpool') {
149 showPool();
150}
151
152# Not modified or added; just shuffled
153elsif($webvar{action} eq 'assign') {
154 assignBlock();
155}
156elsif($webvar{action} eq 'confirm') {
157 confirmAssign();
158}
159elsif($webvar{action} eq 'insert') {
160 insertAssign();
161}
162elsif($webvar{action} eq 'edit') {
163 edit();
164}
165elsif($webvar{action} eq 'update') {
166 update();
167}
168elsif($webvar{action} eq 'delete') {
169 remove();
170}
171elsif($webvar{action} eq 'finaldelete') {
172 finalDelete();
173}
174elsif ($webvar{action} eq 'nodesearch') {
175 my $nodelist = getNodeList($ip_dbh);
176 $page->param(nodelist => $nodelist);
177}
178
179# DB failure. Can't do much here, really.
180elsif ($webvar{action} eq 'dberr') {
181 $page->param(errmsg => $errstr);
182}
183
184# Default is an error. It shouldn't be possible to get here unless you're
185# randomly feeding in values for webvar{action}.
186else {
187 my $rnd = rand 500;
188 my $boing = sprintf("%.2f", rand 500);
189 my @excuses = (
190 "Aether cloudy. Ask again later about $webvar{action}.",
191 "The gods are unhappy with your sacrificial $webvar{action}.",
192 "Because one of $webvar{action}'s legs are both the same",
193 "<b>wibble</b><br>Can't $webvar{action}, the grue will get me!<br>Can't $webvar{action}, the grue will get me!",
194 "Hey, man, you've had your free $webvar{action}. Next one's gonna... <i>cost</i>....",
195 "I ain't done $webvar{action}",
196 "Oooo, look! A flying $webvar{action}!",
197 "$webvar{action} too evil, avoiding.",
198 "Rocks fall, $webvar{action} dies.",
199 "Bit bucket must be emptied before I can $webvar{action}..."
200 );
201 $page->param(dunno => $excuses[$rnd/50.0]);
202}
203## Finally! Done with that NASTY "case" emulation!
204
205
206# Switch to a different template if we've tripped on an ACL error.
207# Note that this should only be exercised in development, when
208# deeplinked, or when being attacked; normal ACL handling should
209# remove the links a user is not allowed to click on.
210if ($aclerr) {
211 $page = HTML::Template->new(filename => "aclerror.tmpl");
212 $page->param(ipdbfunc => $aclmsg{$aclerr});
213}
214
215# Clean up IPDB globals, DB handle, etc.
216finish($ip_dbh);
217
218## Do all our printing here so we can generate errors and stick them into the slots in the templates.
219
220# can't do this yet, too many blowups
221#print "Content-type: text/html\n\n", $header->output;
222$page->param(webpath => $IPDB::webpath);
223print $page->output;
224
225# include the admin tools link in the output?
226$footer->param(adminlink => ($IPDBacl{$authuser} =~ /A/));
227$footer->param(webpath => $IPDB::webpath);
228print $footer->output;
229
230# Just in case something waaaayyy down isn't in place
231# properly... we exit explicitly.
232exit 0;
233
234
235# Initial display: Show master blocks with total allocated subnets, total free subnets
236sub showSummary {
237 my $masterlist = listSummary($ip_dbh);
238 $page->param(masterlist => $masterlist);
239
240 $page->param(addmaster => ($IPDBacl{$authuser} =~ /a/) );
241} # showSummary
242
243
244# Display blocks immediately within a given parent
245sub showSubs {
246 # Which layout?
247 if ($IPDB::sublistlayout == 2) {
248
249 # 2-part layout; mixed containers and end-use allocations and free blocks.
250 # Containers have a second line for the subblock metadata.
251 # We need to load an alternate template for this case.
252 $page = HTML::Template->new(filename => "showsubs2.tmpl", loop_context_vars => 1, global_vars => 1);
253
254 $page->param(maydel => ($IPDBacl{$authuser} =~ /d/));
255
256 my $sublist = listSubs($ip_dbh, parent => $webvar{parent});
257 $page->param(sublist => $sublist);
258
259 } else {
260
261 # 3-part layout; containers, end-use allocations, and free blocks
262
263 my $contlist = listContainers($ip_dbh, parent => $webvar{parent});
264 $page->param(contlist => $contlist);
265
266 my $alloclist = listAllocations($ip_dbh, parent => $webvar{parent});
267 $page->param(alloclist => $alloclist);
268
269 # only show "delete" button if we have no container or usage allocations
270 $page->param(maydel => ($IPDBacl{$authuser} =~ /d/) && !(@$contlist || @$alloclist));
271
272 }
273
274 # Common elements
275 my $pinfo = getBlockData($ip_dbh, $webvar{parent});
276
277##fixme: do we add a wrapper to not show the edit link for master blocks?
278#$page->param(editme => 1) unless $pinfo->{type} ne 'mm';
279
280 $page->param(self_id => $webvar{parent});
281 $page->param(block => $pinfo->{block});
282 $page->param(mayadd => ($IPDBacl{$authuser} =~ /a/));
283
284 my $flist = listFree($ip_dbh, parent => $webvar{parent});
285 $page->param(freelist => $flist);
286} # showSubs
287
288
289# List the IPs used in a pool
290sub showPool {
291
292 my $poolinfo = getBlockData($ip_dbh, $webvar{pool});
293 my $cidr = new NetAddr::IP $poolinfo->{block};
294
295 $page->param(block => $cidr);
296 $page->param(netip => $cidr->addr);
297 $cidr++;
298 $page->param(gate => $cidr->addr);
299 $cidr--; $cidr--;
300 $page->param(bcast => $cidr->addr);
301 $page->param(mask => $cidr->mask);
302
303 $page->param(disptype => $disp_alloctypes{$poolinfo->{type}});
304 $page->param(city => $poolinfo->{city});
305
306 # Only display net/gw/bcast if it's a "real" netblock and not a PPP(oE) lunacy
307 $page->param(realblock => $poolinfo->{type} =~ /^.d$/);
308
309# probably have to add an "edit IP allocation" link here somewhere.
310
311 my $plist = listPool($ip_dbh, $webvar{pool});
312 # technically slightly more efficient to check the ACL in an if () once outside the foreach
313 foreach (@{$plist}) {
314 $$_{maydel} = $IPDBacl{$authuser} =~ /d/;
315 }
316 $page->param(poolips => $plist);
317} # end showPool
318
319
320# Show "Add new allocation" page. Note that the actual page may
321# be one of two templates, and the lists come from the database.
322sub assignBlock {
323
324 if ($IPDBacl{$authuser} !~ /a/) {
325 $aclerr = 'addblock';
326 return;
327 }
328
329 # hack pthbttt eww
330 $webvar{parent} = 0 if !$webvar{parent};
331 $webvar{block} = '' if !$webvar{block};
332
333 $page->param(allocfrom => $webvar{block}); # fb-assign flag, if block is set, we're in fb-assign
334
335 if ($webvar{fbid} || $webvar{fbtype}) {
336
337 # Common case, according to reported usage. Block to assign is specified.
338 my $block = new NetAddr::IP $webvar{block};
339
340 my ($rdns,$cached) = getBlockRDNS($ip_dbh, id => $webvar{parent}, type => $webvar{fbtype}, user => $authuser);
341 $page->param(rdns => $rdns) if $rdns;
342 $page->param(parent => $webvar{parent});
343 $page->param(fbid => $webvar{fbid});
344 # visual flag that we're working IPDB-local, not off more authoritative data in dnsadmin
345 $page->param(cached => $cached);
346
347 my $pinfo = getBlockData($ip_dbh, $webvar{parent});
348 # seems reasonable that a new allocation would share a VRF with its parent
349 $page->param(pvrf => $pinfo->{vrf});
350
351 $webvar{fbtype} = '' if !$webvar{fbtype};
352 if ($webvar{fbtype} eq 'i') {
353 my $ipinfo = getBlockData($ip_dbh, $webvar{block}, 'i');
354 $page->param(
355 fbip => 1,
356 block => $ipinfo->{block},
357 fbdisptype => $list_alloctypes{$ipinfo->{type}},
358 type => $ipinfo->{type},
359 allocfrom => $pinfo->{block},
360 );
361 } else {
362 # get "primary" alloctypes, since these are all that can correctly be assigned if we're in this branch
363 my $tlist = getTypeList($ip_dbh, 'n');
364 $tlist->[0]->{sel} = 1;
365 $page->param(typelist => $tlist, block => $block);
366 }
367
368 } else {
369
370 # Uncommon case, according to reported usage. Block to assign needs to be found based on criteria.
371 my $mlist = getMasterList($ip_dbh, 'c');
372 $page->param(masterlist => $mlist);
373
374 my @pops;
375 foreach my $pop (@citylist) {
376 my %row = (pop => $pop);
377 push (@pops, \%row);
378 }
379 $page->param(pops => \@pops);
380
381 # get all standard alloctypes
382 my $tlist = getTypeList($ip_dbh, 'a');
383 $tlist->[0]->{sel} = 1;
384 $page->param(typelist => $tlist);
385 }
386
387 my @cities;
388 foreach my $city (@citylist) {
389 my %row = (city => $city);
390 push (@cities, \%row);
391 }
392 $page->param(citylist => \@cities);
393
394## node hack
395 my $nlist = getNodeList($ip_dbh);
396 $page->param(nodelist => $nlist);
397## end node hack
398
399 $page->param(privdata => $IPDBacl{$authuser} =~ /s/);
400
401} # assignBlock
402
403
404# Take info on requested IP assignment and see what we can provide.
405sub confirmAssign {
406 if ($IPDBacl{$authuser} !~ /a/) {
407 $aclerr = 'addblock';
408 return;
409 }
410
411 my $cidr;
412 my $resv; # Reserved for expansion.
413 my $alloc_from;
414 my $fbid = $webvar{fbid};
415 my $p_id = $webvar{parent};
416
417 # Going to manually validate some items.
418 # custid and city are automagic.
419 return if !validateInput();
420
421 # make sure this is defined
422 $webvar{fbassign} = 'n' if !$webvar{fbassign};
423
424# Several different cases here.
425# Static IP vs netblock
426# + Different flavours of static IP
427# + Different flavours of netblock
428
429 if ($webvar{alloctype} =~ /^.i$/ && $webvar{fbassign} ne 'y') {
430 if (!$webvar{pop}) {
431 $page->param(err => "Please select a location/POP site to allocate from.");
432 return;
433 }
434 my $plist = getPoolSelect($ip_dbh, $webvar{alloctype}, $webvar{pop});
435 $page->param(staticip => 1);
436 $page->param(poollist => $plist) if $plist;
437 $cidr = "Single static IP";
438##fixme: need to handle "no available pools"
439
440 } else { # end show pool options
441
442 if ($webvar{fbassign} && $webvar{fbassign} eq 'y') {
443 $cidr = new NetAddr::IP $webvar{block};
444 $alloc_from = new NetAddr::IP $webvar{allocfrom};
445 $webvar{maskbits} = $cidr->masklen;
446 # Some additional checks are needed for reserving free space
447 if ($webvar{reserve}) {
448 if ($cidr == $alloc_from) {
449# We could still squirm and fiddle to try to find a way to reserve space, but the storage model for
450# IPDB means that all continguous free space is kept in the smallest number of strict CIDR netblocks
451# possible. (In theory.) If the request and the freeblock are the same, it is theoretically impossible
452# to reserve an equivalent-sized block either ahead or behind the requested one, because the pair
453# together would never be a strict CIDR block.
454 $page->param(warning => "Can't reserve space for expansion; free block and requested allocation are the same.");
455 delete $webvar{reserve};
456 } else {
457 # Find which new free block will match the reqested block.
458 # Take the requested mask, shift by one
459 my $tmpmask = $webvar{maskbits};
460 $tmpmask--;
461 # find the subnets with that mask in the selected free block
462 my @pieces = $alloc_from->split($tmpmask);
463 foreach my $slice (@pieces) {
464 if ($slice->contains($cidr)) {
465 # For the subnet that contains the requested block, split that in two,
466 # and flag/cache the one that's not the requested block.
467 my @bits = $slice->split($webvar{maskbits});
468 if ($bits[0] == $cidr) {
469 $resv = $bits[1];
470 } else {
471 $resv = $bits[0];
472 }
473 }
474 }
475 }
476 } # reserve block check
477
478 } else { # done with direct freeblocks assignment
479
480 if (!$webvar{maskbits}) {
481 $page->param(err => "Please specify a CIDR mask length.");
482 return;
483 }
484
485##fixme ick, ew, bleh. gotta handle the failure message generation better. push it into findAllocateFrom()?
486 my $failmsg = "No suitable free block found.<br>\n";
487 if ($webvar{alloctype} eq 'rm') {
488 $failmsg .= "We do not have a free routeable block of that size.<br>\n".
489 "You will have to either route a set of smaller netblocks or a single smaller netblock.";
490 } else {
491 if ($webvar{alloctype} =~ /^.[pc]$/) {
492 $failmsg .= "You will have to route another superblock from one of the<br>\n".
493 "master blocks or chose a smaller block size for the pool.";
494 } else {
495 if (!$webvar{pop}) {
496 $page->param(err => 'Please select a POP to route the block from/through.');
497 return;
498 }
499 $failmsg .= "You will have to route another superblock to $webvar{pop}<br>\n".
500 "from one of the master blocks";
501 if ($webvar{reserve}) {
502 $failmsg .= ', choose a smaller blocksize, or uncheck "Reserve space for expansion".';
503 } else {
504 $failmsg .= " or chose a smaller blocksize.";
505 }
506 }
507 }
508
509 # if requesting extra space "reserved for expansion", we need to find a free
510 # block at least double the size of the request.
511 if ($webvar{reserve}) {
512 $webvar{maskbits}--;
513 }
514
515 ($fbid,$cidr,$p_id) = findAllocateFrom($ip_dbh, $webvar{maskbits}, $webvar{alloctype},
516 $webvar{city}, $webvar{pop}, (master => $webvar{allocfrom}, allowpriv => $webvar{allowpriv}) );
517 if (!$cidr) {
518 $page->param(err => $failmsg);
519 return;
520 }
521 $cidr = new NetAddr::IP $cidr;
522
523 $alloc_from = "$cidr";
524
525 # when autofinding a block to allocate from, use the first piece of the found
526 # block for the allocation, and the next piece for the "reserved for expansion".
527 if ($webvar{reserve}) {
528 # reset the mask to the real requested one, now that we've got a
529 # block large enough for the request plus reserve
530 $webvar{maskbits}++;
531 ($cidr,$resv) = $cidr->split($webvar{maskbits});
532 }
533
534 # If the block to be allocated is smaller than the one we found,
535 # figure out the "real" block to be allocated.
536 if ($cidr->masklen() ne $webvar{maskbits}) {
537 my $maskbits = $cidr->masklen();
538 my @subblocks;
539 while ($maskbits++ < $webvar{maskbits}) {
540 @subblocks = $cidr->split($maskbits);
541 }
542 $cidr = $subblocks[0];
543 }
544 } # check for freeblocks assignment or IPDB-controlled assignment
545
546 # Generate the IP list for the new allocation in case someone wants to set per-IP rDNS right away.
547 # We don't do this on the previous page because we don't know how big a block or even what IP range
548 # it's for (if following the "normal" allocation process)
549 if ($IPDBacl{$authuser} =~ /c/
550 && $cidr->masklen != $cidr->bits
551 && ($cidr->bits - $cidr->masklen) <= $IPDB::maxrevlist
552 && $webvar{alloctype} !~ /^.[dpi]/
553 # do we want to allow v6 at all?
554 #&& ! $cidr->{isv6}
555 ) {
556 my @list;
557 foreach my $ip (@{$cidr->splitref()}) {
558 my %row;
559 $row{r_ip} = $ip->addr;
560 $row{iphost} = '';
561 push @list, \%row;
562 }
563 $page->param(r_iplist => \@list);
564 # We don't use this here, because these IPs should already be bare.
565 # ... or should we be paranoid? Make it a config option?
566 #getRDNSbyIP($ip_dbh, type => $webvar{alloctype}, range => "$cidr", user => $authuser) );
567 }
568 } # if ($webvar{alloctype} =~ /^.i$/)
569
570## node hack
571 if ($webvar{node} && $webvar{node} ne '-') {
572 my $nodename = getNodeName($ip_dbh, $webvar{node});
573 $page->param(nodename => $nodename);
574 $page->param(nodeid => $webvar{node});
575 }
576## end node hack
577
578 # reserve for expansion
579 $page->param(reserve => $webvar{reserve});
580 # probably just preventing a little log noise doing this; could just set the param
581 # all the time since it won't be shown if the reserve param above isn't set.
582# if ($webvar{reserve}) {
583 $page->param(resvblock => $resv);
584# }
585
586 # Stick in the allocation data
587 $page->param(alloc_type => $webvar{alloctype});
588 $page->param(typefull => $q->escapeHTML($disp_alloctypes{$webvar{alloctype}}));
589 $page->param(alloc_from => $alloc_from);
590 $page->param(parent => $p_id);
591 $page->param(fbid => $fbid);
592 $page->param(cidr => $cidr);
593 $page->param(rdns => $webvar{rdns});
594 $page->param(vrf => $webvar{vrf});
595 $page->param(vlan => $webvar{vlan});
596 $page->param(city => $q->escapeHTML($webvar{city}));
597 $page->param(custid => $webvar{custid});
598 $page->param(circid => $q->escapeHTML($webvar{circid}));
599 $page->param(desc => $q->escapeHTML($webvar{desc}));
600
601##fixme: find a way to have the displayed copy have <br> substitutions
602# for newlines, and the <input> value have either encoded or bare newlines.
603# Also applies to privdata.
604 $page->param(notes => $q->escapeHTML($webvar{notes},'y'));
605
606 # Check to see if user is allowed to do anything with sensitive data
607 my $privdata = '';
608 $page->param(privdata => $q->escapeHTML($webvar{privdata},'y'))
609 if $IPDBacl{$authuser} =~ /s/;
610
611 # Yay! This now has it's very own little home.
612 $page->param(billinguser => $webvar{userid})
613 if $webvar{userid};
614
615##fixme: this is only needed iff confirm.tmpl and
616# confirmRemove.tmpl are merged (quite possible, just
617# a little tedious)
618 $page->param(action => "insert");
619
620} # end confirmAssign
621
622
623# Do the work of actually inserting a block in the database.
624sub insertAssign {
625 if ($IPDBacl{$authuser} !~ /a/) {
626 $aclerr = 'addblock';
627 return;
628 }
629 # Some things are done more than once.
630 return if !validateInput();
631
632 if (!defined($webvar{privdata})) {
633 $webvar{privdata} = '';
634 }
635
636 # split up some linked data for static IPs via guided allocation. needed for breadcrumbs lite.
637 ($webvar{alloc_from},$webvar{rdepth}) = split /,/, $webvar{alloc_from} if $webvar{alloc_from} =~ /,/;
638
639 # $code is "success" vs "failure", $msg contains OK for a
640 # successful netblock allocation, the IP allocated for static
641 # IP, or the error message if an error occurred.
642
643##fixme: consider just passing \%webvar to allocateBlock()?
644 # collect per-IP rDNS fields. only copy over the ones that actually have something in them.
645 my %iprev;
646 foreach (keys %webvar) {
647 $iprev{$_} = $webvar{$_} if /host_[\d.a-fA-F:]+/ && $webvar{$_};
648 }
649
650 # Easier to see and cosmetically fiddle the list like this
651 my %insert_args = (
652 cidr => $webvar{fullcidr},
653 fbid => $webvar{fbid},
654 reserve => $webvar{reserve},
655 parent => $webvar{parent},
656 custid => $webvar{custid},
657 type => $webvar{alloctype},
658 city => $webvar{city},
659 desc => $webvar{desc},
660 notes => $webvar{notes},
661 circid => $webvar{circid},
662 privdata => $webvar{privdata},
663 nodeid => $webvar{node},
664 rdns => $webvar{rdns},
665 vrf => $webvar{vrf},
666 vlan => $webvar{vlan},
667 user => $authuser,
668 );
669
670 my ($code,$msg) = allocateBlock($ip_dbh, %insert_args, iprev => \%iprev);
671
672 if ($code eq 'OK') {
673 if ($webvar{alloctype} =~ /^.i$/) {
674 $msg =~ s|/32||;
675 $page->param(staticip => $msg);
676 $page->param(custid => $webvar{custid});
677 $page->param(parent => $webvar{parent}, pool => $webvar{alloc_from});
678 $page->param(billinguser => $webvar{billinguser});
679 mailNotify($ip_dbh, "a$webvar{alloctype}", "ADDED: $disp_alloctypes{$webvar{alloctype}} allocation",
680 "$disp_alloctypes{$webvar{alloctype}} $msg allocated to customer $webvar{custid}\n".
681 "Description: $webvar{desc}\n\nAllocated by: $authuser\n");
682 } else {
683 my $netblock = new NetAddr::IP $webvar{fullcidr};
684 $page->param(fullcidr => $webvar{fullcidr});
685 $page->param(alloctype => $disp_alloctypes{$webvar{alloctype}});
686 $page->param(custid => $webvar{custid});
687 # breadcrumbs lite! provide at least a link to the parent of the block we just allocated.
688 my $binfo = getBlockData($ip_dbh, $webvar{parent});
689 $page->param(parentid => $webvar{parent});
690 $page->param(parentblock => $binfo->{block});
691 if ($webvar{alloctype} eq 'pr' && $webvar{billinguser}) {
692 $page->param(billinguser => $webvar{billinguser});
693 $page->param(custid => $webvar{custid});
694 $page->param(netaddr => $netblock->addr);
695 $page->param(masklen => $netblock->masklen);
696 }
697 mailNotify($ip_dbh, "a$webvar{alloctype}", "ADDED: $disp_alloctypes{$webvar{alloctype}} allocation",
698 "$disp_alloctypes{$webvar{alloctype}} $webvar{fullcidr} allocated to customer $webvar{custid}\n".
699 "Description: $webvar{desc}\n\nAllocated by: $authuser\n");
700 }
701 syslog "notice", "$authuser allocated '$webvar{fullcidr}' to '$webvar{custid}' as ".
702 "'$webvar{alloctype}' ($msg)";
703 } else {
704 syslog "err", "Allocation of '$webvar{fullcidr}' to '$webvar{custid}' as ".
705 "'$webvar{alloctype}' by $authuser failed: '$msg'";
706 $page->param(err => "Allocation of $webvar{fullcidr} as '$disp_alloctypes{$webvar{alloctype}}'".
707 " failed:<br>\n$msg\n");
708 }
709
710} # end insertAssign()
711
712
713# Does some basic checks on common input data to make sure nothing
714# *really* weird gets in to the database through this script.
715# Does NOT do complete input validation!!!
716sub validateInput {
717 if ($webvar{city} eq '-') {
718 $page->param(err => 'Please choose a city');
719 return;
720 }
721
722 # Alloctype check.
723 chomp $webvar{alloctype};
724 if (!grep /$webvar{alloctype}/, keys %disp_alloctypes) {
725 # Danger! Danger! alloctype should ALWAYS be set by a dropdown. Anyone
726 # managing to call things in such a way as to cause this deserves a cryptic error.
727 $page->param(err => 'Invalid alloctype');
728 return;
729 }
730
731 # CustID check
732 # We have different handling for customer allocations and "internal" or "our" allocations
733 if ($def_custids{$webvar{alloctype}} eq '') {
734 if (!$webvar{custid}) {
735 $page->param(err => 'Please enter a customer ID.');
736 return;
737 }
738 # Crosscheck with billing.
739 my $status = CustIDCK->custid_exist($webvar{custid});
740 if ($CustIDCK::Error) {
741 $page->param(err => "Error verifying customer ID: ".$CustIDCK::ErrMsg);
742 return;
743 }
744 if (!$status) {
745 $page->param(err => "Customer ID not valid. Make sure the Customer ID ".
746 "is correct.<br>\nUse STAFF for staff static IPs, and $IPDB::defcustid for any other ".
747 "non-customer assignments.");
748 return;
749 }
750# print "<!-- [ In validateInput(). Insert customer ID cross-check here. ] -->\n";
751 } else {
752 # New! Improved! And now Loaded From The Database!!
753 if ((!$webvar{custid}) || ($webvar{custid} ne 'STAFF')) {
754 $webvar{custid} = $def_custids{$webvar{alloctype}};
755 }
756 }
757
758## hmmm.... is this even useful?
759if (0) {
760 # Check POP location
761 my $flag;
762 if ($webvar{alloctype} eq 'rm') {
763 $flag = 'for a routed netblock';
764 foreach (@poplist) {
765 if (/^$webvar{city}$/) {
766 $flag = 'n';
767 last;
768 }
769 }
770 } else {
771 $flag = 'n';
772##fixme: hook to force-set POP or city on certain alloctypes
773# if ($webvar{alloctype =~ /foo,bar,bz/ { $webvar{pop} = 'blah'; }
774 if ($webvar{pop} && $webvar{pop} =~ /^-$/) {
775 $flag = 'to route the block from/through';
776 }
777 }
778
779 # if the alloctype has a restricted city/POP list as determined above,
780 # and the reqested city/POP does not match that list, complain
781 if ($flag ne 'n') {
782 $page->param(err => "Please choose a valid POP location $flag. Valid ".
783 "POP locations are currently:<br>\n".join (" - ", @poplist));
784 return;
785 }
786}
787
788 # VRF. Not a full validity check, just a basic sanity check.
789 if ($webvar{vrf}) {
790 # Trim leading and trailing whitespace first
791 $webvar{vrf} =~ s/^\s+//;
792 $webvar{vrf} =~ s/\s+$//;
793 if ($webvar{vrf} !~ /^[\w\d_.-]{1,32}$/) {
794 $page->param(err => "VRF values may only contain alphanumerics, and may not be more than 32 characters");
795 return;
796 }
797 }
798
799 # VLAN. Should we allow/use VLAN names, or just the numeric ID?
800 if ($webvar{vlan}) {
801 # Trim leading and trailing whitespace first
802 $webvar{vlan} =~ s/^\s+//;
803 $webvar{vlan} =~ s/\s+$//;
804 # ... ve make it ze configurable thingy!
805 if ($IPDB::numeric_vlan) {
806 if ($webvar{vlan} !~ /^\d+$/) {
807 $page->param(err => "VLANs must be numeric");
808 return;
809 }
810 } else {
811 if ($webvar{vlan} !~ /^[\w\d_.-]+$/) {
812 $page->param(err => "VLANs must be alphanumeric");
813 return;
814 }
815 }
816 }
817
818 return 'OK';
819} # end validateInput
820
821
822# Displays details of a specific allocation in a form
823# Allows update/delete
824# action=edit
825sub edit {
826
827 # snag block info from db
828 my $blockinfo = getBlockData($ip_dbh, $webvar{id}, $webvar{basetype});
829 $page->param(id => $webvar{id});
830 $page->param(basetype => $webvar{basetype});
831
832 # Clean up extra whitespace on alloc type. Mainly a legacy-data cleanup.
833 $blockinfo->{type} =~ s/\s//;
834
835 my $cached;
836 # Get rDNS info; duplicates a bit of getBlockData but also does the RPC call if possible
837 ($blockinfo->{rdns},$cached) = getBlockRDNS($ip_dbh, id => $webvar{id}, type => $blockinfo->{type}, user => $authuser);
838 # visual flag that we're working IPDB-local, not off more authoritative data in dnsadmin
839 $page->param(cached => $cached);
840
841 my $cidr = new NetAddr::IP $blockinfo->{block};
842 # Limit the per-IP rDNS list based on CIDR length; larger ones just take up too much space.
843 # Also, don't show on IP pools; the individual IPs will have a space for rDNS
844 # Don't show on single IPs; these use the "pattern" field
845 if ($IPDBacl{$authuser} =~ /c/
846 && $cidr->masklen != $cidr->bits
847 && ($cidr->bits - $cidr->masklen) <= $IPDB::maxrevlist
848 && $blockinfo->{type} !~ /^.[dpi]/
849 # do we want to allow v6 at all?
850 #&& ! $cidr->{isv6}
851 ) {
852 $page->param(r_iplist => getRDNSbyIP($ip_dbh, id => $webvar{id}, type => $blockinfo->{type},
853 range => $blockinfo->{block}, user => $authuser) );
854 }
855
856 # consider extending this to show time as well as date
857 my ($lastmod,undef) = split /\s+/, $blockinfo->{lastmod};
858 $page->param(lastmod => $lastmod);
859# $page->param(lastmod => $blockinfo->{lastmod});
860
861 $page->param(block => $blockinfo->{block});
862 $page->param(city => $blockinfo->{city});
863 $page->param(custid => $blockinfo->{custid});
864
865##fixme The check here should be built from the database
866# Need to expand to support pool types too
867 if ($blockinfo->{type} =~ /^.[ne]$/ && $IPDBacl{$authuser} =~ /c/) {
868 $page->param(changetype => 1);
869 $page->param(alloctype => [
870 { selme => ($blockinfo->{type} eq 'me'), type => "me", disptype => "Dialup netblock" },
871 { selme => ($blockinfo->{type} eq 'de'), type => "de", disptype => "Dynamic DSL netblock" },
872 { selme => ($blockinfo->{type} eq 'ce'), type => "ce", disptype => "Dynamic cable netblock" },
873 { selme => ($blockinfo->{type} eq 'we'), type => "we", disptype => "Dynamic wireless netblock" },
874 { selme => ($blockinfo->{type} eq 'cn'), type => "cn", disptype => "Customer netblock" },
875 { selme => ($blockinfo->{type} eq 'en'), type => "en", disptype => "End-use netblock" },
876 { selme => ($blockinfo->{type} eq 'in'), type => "in", disptype => "Internal netblock" },
877 ]
878 );
879 } else {
880 $page->param(disptype => $disp_alloctypes{$blockinfo->{type}});
881 $page->param(type => $blockinfo->{type});
882 }
883
884## node hack
885 my ($nodeid,$nodename) = getNodeInfo($ip_dbh, $blockinfo->{block});
886# $page->param(havenodeid => $nodeid);
887 $page->param(nodename => $nodename);
888
889##fixme: this whole hack needs cleanup and generalization for all alloctypes
890##fixme: arguably a bug that presence of a nodeid implies it can be changed..
891 if ($IPDBacl{$authuser} =~ /c/) {
892 my $nlist = getNodeList($ip_dbh);
893 if ($nodeid) {
894 foreach (@{$nlist}) {
895 $$_{selme} = ($$_{node_id} == $nodeid);
896 }
897 }
898 $page->param(nodelist => $nlist);
899 }
900## end node hack
901
902 $page->param(rdns => $blockinfo->{rdns});
903 $page->param(vrf => $blockinfo->{vrf});
904 $page->param(vlan => $blockinfo->{vlan});
905
906 # not happy with the upside-down logic, but...
907 $page->param(swipable => $blockinfo->{type} !~ /.i/);
908 $page->param(swip => $blockinfo->{swip} ne 'n') if $blockinfo->{swip};
909
910 $page->param(circid => $blockinfo->{circuitid});
911 $page->param(desc => $blockinfo->{description});
912 $page->param(notes => $blockinfo->{notes});
913
914 # Check to see if we can display sensitive data
915 $page->param(nocling => $IPDBacl{$authuser} =~ /s/);
916 $page->param(privdata => $blockinfo->{privdata});
917
918 # ACL trickery - these two template booleans control the presence of all form/input tags
919 $page->param(maychange => $IPDBacl{$authuser} =~ /c/);
920 $page->param(maydel => $IPDBacl{$authuser} =~ /d/);
921
922} # edit()
923
924
925# Stuff new info about a block into the db
926# action=update
927sub update {
928 if ($IPDBacl{$authuser} !~ /c/) {
929 $aclerr = 'updateblock';
930 return;
931 }
932
933 # Make sure incoming data is in correct format - custID among other things.
934 return if !validateInput;
935
936 $webvar{swip} = 'n' if !$webvar{swip};
937
938 my %updargs = (
939 custid => $webvar{custid},
940 city => $webvar{city},
941 description => $webvar{desc},
942 notes => $webvar{notes},
943 circuitid => $webvar{circid},
944 block => $webvar{block},
945 type => $webvar{alloctype},
946 swip => $webvar{swip},
947 rdns => $webvar{rdns},
948 vrf => $webvar{vrf},
949 vlan => $webvar{vlan},
950 user => $authuser,
951 );
952
953 # Semioptional values
954 $updargs{privdata} = $webvar{privdata} if $IPDBacl{$authuser} =~ /s/;
955 $updargs{node} = $webvar{node} if $webvar{node};
956
957 # collect per-IP rDNS fields. only copy over the ones that actually have something in them.
958 my %iprev;
959 foreach (keys %webvar) {
960 $iprev{$_} = $webvar{$_} if /host_[\d.a-fA-F:]+/ && $webvar{$_};
961 }
962
963 my ($code,$msg) = updateBlock($ip_dbh, %updargs, iprev => \%iprev);
964
965 if ($code eq 'FAIL') {
966 syslog "err", "$authuser could not update block/IP '$webvar{block}': '$msg'";
967 $page->param(err => "Could not update block/IP $webvar{block}: $msg");
968 return;
969 }
970
971 # If we get here, the operation succeeded.
972 syslog "notice", "$authuser updated $webvar{block}";
973##fixme: log details of the change? old way is in the .debug stream anyway.
974##fixme: need to wedge something in to allow "update:field" notifications
975## hmm. how to tell what changed? O_o
976mailNotify($ip_dbh, 's:swi', "SWIPed: $disp_alloctypes{$webvar{alloctype}} $webvar{block}",
977 "$webvar{block} had SWIP status changed to \"Yes\" by $authuser") if $webvar{swip} eq 'on';
978
979## node hack
980 if ($webvar{node} && $webvar{node} ne '-') {
981 my $nodename = getNodeName($ip_dbh, $webvar{node});
982 $page->param(nodename => $nodename);
983 }
984## end node hack
985
986 # Link back to browse-routed or list-pool page on "Update complete" page.
987 my $binfo = getBlockData($ip_dbh, $webvar{block}, $webvar{basetype});
988 my $pblock = getBlockData($ip_dbh, $binfo->{parent_id});
989 $page->param(backid => $binfo->{parent_id});
990 $page->param(backblock => $pblock->{block});
991 $page->param(backpool => ($webvar{basetype} eq 'i'));
992
993 # Do some HTML fiddling here instead of using ESCAPE=HTML in the template,
994 # because otherwise we can't convert \n to <br>. *sigh*
995 $webvar{notes} = $q->escapeHTML($webvar{notes}); # escape first...
996 $webvar{notes} =~ s/\n/<br>\n/; # ... then convert newlines
997 $webvar{privdata} = ($webvar{privdata} ? $q->escapeHTML($webvar{privdata}) : "&nbsp;");
998 $webvar{privdata} =~ s/\n/<br>\n/;
999
1000 $page->param(cidr => $binfo->{block});
1001 $page->param(rdns => $webvar{rdns});
1002 $page->param(city => $webvar{city});
1003 $page->param(disptype => $disp_alloctypes{$webvar{alloctype}});
1004 $page->param(custid => $webvar{custid});
1005 $page->param(swip => $webvar{swip} eq 'on' ? 'Yes' : 'No');
1006 $page->param(circid => $webvar{circid});
1007 $page->param(desc => $webvar{desc});
1008 $page->param(notes => $webvar{notes});
1009 $page->param(privdata => $webvar{privdata})
1010 if $IPDBacl{$authuser} =~ /s/;
1011
1012} # update()
1013
1014
1015# Delete an allocation.
1016sub remove {
1017 if ($IPDBacl{$authuser} !~ /d/) {
1018 $aclerr = 'delblock';
1019 return;
1020 }
1021
1022 # Serves'em right for getting here...
1023 if (!defined($webvar{block})) {
1024 $page->param(err => "Can't delete a block that doesn't exist");
1025 return;
1026 }
1027
1028 my $blockdata;
1029 $blockdata = getBlockData($ip_dbh, $webvar{block}, $webvar{basetype});
1030
1031 if ($blockdata->{parent_id} == 0) { # $webvar{alloctype} eq 'mm'
1032 $blockdata->{city} = "N/A";
1033 $blockdata->{custid} = "N/A";
1034 $blockdata->{circuitid} = "N/A";
1035 $blockdata->{description} = "N/A";
1036 $blockdata->{notes} = "N/A";
1037 $blockdata->{privdata} = "N/A";
1038 } # end cases for different alloctypes
1039
1040 $page->param(blockid => $webvar{block});
1041 $page->param(basetype => $webvar{basetype});
1042
1043 $page->param(block => $blockdata->{block});
1044 $page->param(rdns => $blockdata->{rdns});
1045
1046 # maybe need to apply more magic here?
1047 # most allocations we *do* want to autodelete the forward as well as reverse; for a handful we don't.
1048 # -> all real blocks (nb: pool IPs need extra handling)
1049 # -> NOC/private-IP (how to ID?)
1050 # -> anything with a pattern matching $IPDB::domain?
1051 if ($blockdata->{type} !~ /^.i$/) {
1052 $page->param(autodel => 1);
1053 }
1054
1055 $page->param(disptype => $disp_alloctypes{$blockdata->{type}});
1056 $page->param(city => $blockdata->{city});
1057 $page->param(custid => $blockdata->{custid});
1058 $page->param(circid => $blockdata->{circuitid});
1059 $page->param(desc => $blockdata->{description});
1060 $blockdata->{notes} = $q->escapeHTML($blockdata->{notes});
1061 $blockdata->{notes} =~ s/\n/<br>\n/;
1062 $page->param(notes => $blockdata->{notes});
1063 $blockdata->{privdata} = $q->escapeHTML($blockdata->{privdata});
1064 $blockdata->{privdata} = '&nbsp;' if !$blockdata->{privdata};
1065 $blockdata->{privdata} =~ s/\n/<br>\n/;
1066 $page->param(privdata => $blockdata->{privdata}) if $IPDBacl{$authuser} =~ /s/;
1067 $page->param(delpool => $blockdata->{type} =~ /^.[pd]$/);
1068
1069} # end remove()
1070
1071
1072# Delete an allocation. Return it to the freeblocks table; munge
1073# data as necessary to keep as few records as possible in freeblocks
1074# to prevent weirdness when allocating blocks later.
1075# Remove IPs from pool listing if necessary
1076sub finalDelete {
1077 if ($IPDBacl{$authuser} !~ /d/) {
1078 $aclerr = 'delblock';
1079 return;
1080 }
1081
1082 # need to retrieve block data before deleting so we can notify on that
1083 my $blockinfo = getBlockData($ip_dbh, $webvar{block}, $webvar{basetype});
1084 my $pinfo = getBlockData($ip_dbh, $blockinfo->{parent_id}, 'b');
1085
1086 my ($code,$msg) = deleteBlock($ip_dbh, $webvar{block}, $webvar{basetype}, $webvar{delforward}, $authuser);
1087
1088 $page->param(block => $blockinfo->{block});
1089 $page->param(bdisp => $q->escapeHTML($disp_alloctypes{$blockinfo->{type}}));
1090 $page->param(delparent_id => $blockinfo->{parent_id});# if $webvar{rdepth};
1091 if ($pinfo) {
1092 $page->param(delparent => $pinfo->{block});
1093 $page->param(pdisp => $q->escapeHTML($disp_alloctypes{$pinfo->{type}}));
1094 }
1095 $page->param(returnpool => ($webvar{basetype} eq 'i') );
1096 if ($code =~ /^WARN(POOL|MERGE)/) {
1097 my ($pid,$pcidr) = split /,/, $msg;
1098 my $real_pinfo = getBlockData($ip_dbh, $pid, 'b');
1099 $page->param(parent_id => $pid);
1100 $page->param(parent => $pcidr);
1101 $page->param(real_disp => $q->escapeHTML($disp_alloctypes{$real_pinfo->{type}}));
1102 $page->param(mergeip => $code eq 'WARNPOOL');
1103 }
1104 if ($code eq 'WARN') {
1105 $msg =~ s/\n/<br>\n/g;
1106 $page->param(genwarn => $msg);
1107 }
1108 if ($code eq 'OK' || $code =~ /^WARN/) {
1109 syslog "notice", "$authuser deallocated '".$blockinfo->{type}."'-type netblock $webvar{block} ".
1110 $blockinfo->{custid}.", ".$blockinfo->{city}.", desc='".$blockinfo->{description}."'";
1111 mailNotify($ip_dbh, 'da', "REMOVED: ".$disp_alloctypes{$blockinfo->{type}}." $webvar{block}",
1112 $disp_alloctypes{$blockinfo->{type}}." $webvar{block} deallocated by $authuser\n".
1113 "CustID: ".$blockinfo->{custid}."\nCity: ".$blockinfo->{city}.
1114 "\nDescription: ".$blockinfo->{description}."\n");
1115 } else {
1116 $page->param(failmsg => $msg);
1117 if ($webvar{alloctype} =~ /^.i$/) {
1118 syslog "err", "$authuser could not deallocate static IP '$webvar{block}': '$msg'";
1119 } else {
1120 syslog "err", "$authuser could not deallocate netblock '$webvar{block}': '$msg'";
1121 $page->param(netblock => 1);
1122 }
1123 }
1124
1125} # finalDelete
Note: See TracBrowser for help on using the repository browser.