Changeset 725 for trunk

Timestamp:

05/20/15 14:16:54 (9 years ago)

Author:

Kris Deugau

Message:

/trunk

Add utility sub _poolToAllocations() to support complex block merges,
and type-mapping hash %poolmap to map pool IP types to the "right" type
of allocation. See #8.

File:

• trunk/cgi-bin/IPDB.pm (modified) (2 diffs)

trunk/cgi-bin/IPDB.pm

@@ -64 +64 @@
 our @poplist;
 our %IPDBacl;
+
+# Mapping hash for pooltype -> poolip-as-netblock conversions
+my %poolmap = (sd => 'en', cd => 'cn', dp => 'cn', mp => 'cn', wp => 'cn', ld => 'in', ad => 'in', bd => 'in');
 
 # mapping table for functional-area => error message
@@ -207 +210 @@
 
 } # end _compactFree()
+
+
+## IPDB::_poolToAllocations
+# Convert pool IPs into allocations, and free IPs into free blocks
+# Takes a pool ID, original pool CIDR (in case the allocation has been updated before the call here)
+# and hashref to data for the new parent container for the IPs,
+# and an optional hash with the new parent ID and allocation type
+sub _poolToAllocations {
+  my $dbh = shift;
+  my $oldpool = shift;
+  my $parentinfo = shift;
+  my %args = @_;
+
+  # Default to converting the pool to a container
+  $args{newparent} = $oldpool->{id} if !$args{newparent};
+
+  my ($containerclass) = ($parentinfo->{type} =~ /(.)./);
+
+  # Default type mapping
+  $args{newtype} = $poolmap{$oldpool->{type}} if !$args{newtype};
+
+  # Convert a bunch of pool IP allocations into "normal" netblock allocations
+  my $pool2alloc = $dbh->prepare(q{
+      INSERT INTO allocations (
+              cidr,type,city, description, notes, circuitid, createstamp, modifystamp,
+              privdata, custid, vrf, vlan, rdns, parent_id, master_id
+          )
+      SELECT
+              ip, ? AS type, city, description, notes, circuitid, createstamp, modifystamp,
+              privdata, custid, vrf, vlan, rdns, ? AS parent_id, master_id
+          FROM poolips
+          WHERE parent_id = ? AND available = 'n'
+      });
+  $pool2alloc->execute($args{newtype}, $args{newparent}, $oldpool->{id});
+
+  # Snag the whole list of pool IPs
+  my @freeips = @{$dbh->selectall_arrayref("SELECT ip,available FROM poolips WHERE parent_id = ?",
+        undef, $oldpool->{id})};
+  my @iplist;
+  my %usedips;
+  # Filter out the ones that were used...
+  foreach my $ip (@freeips) {
+    $$ip[0] =~ s{/32$}{};
+    push @iplist, NetAddr::IP->new($$ip[0]) if $$ip[1] eq 'y';
+    $usedips{$$ip[0]}++ if $$ip[1] eq 'n';
+  }
+  # ... so that we can properly decide whether the net, gw, and bcast IPs need to be added to the free list.
+  my $tmpblock = new NetAddr::IP $oldpool->{block};
+  push @iplist, NetAddr::IP->new($tmpblock->network->addr)
+     if !$usedips{$tmpblock->network->addr} || $tmpblock->network->addr =~ /\.0$/;
+  push @iplist, NetAddr::IP->new($tmpblock->broadcast->addr)
+     if !$usedips{$tmpblock->broadcast->addr} || $tmpblock->broadcast->addr =~ /\.255$/;
+  # only "DHCP"-ish pools have a gw ip removed from the pool
+  if ($oldpool->{type} =~ /.d/) {
+    $tmpblock++;
+    push @iplist, NetAddr::IP->new($tmpblock->addr);
+  }
+
+  # take the list of /32 IPs, and see what CIDR ranges we get back as free, then insert them.
+  @iplist = Compact(@iplist);
+  my $insfbsth = $dbh->prepare("INSERT INTO freeblocks (cidr,city,routed,vrf,parent_id,master_id) VALUES (?,?,?,?,?,?)");
+  foreach (@iplist) {
+    $insfbsth->execute($_, $parentinfo->{city}, $containerclass, $parentinfo->{vrf},
+                       $args{newparent}, $parentinfo->{master_id});
+  }
+
+  # and finally delete the poolips entries
+  $dbh->do("DELETE FROM poolips WHERE parent_id = ?", undef, $oldpool->{id});
+
+} # end _poolToAllocations()