Changeset 736

Timestamp:

05/28/15 13:23:29 (9 years ago)

Author:

Kris Deugau

Message:

/trunk

Add internal utility sub _toPool() needed for merge-to-pool. See #8.

File:

• trunk/cgi-bin/IPDB.pm (modified) (1 diff)

trunk/cgi-bin/IPDB.pm

@@ -218 +218 @@
 
 } # end _compactFree()
+
+
+## IPDB::_toPool()
+# Convert an allocation or allocation tree to entries in an IP pool
+# Assumes an incomplete/empty pool
+# Takes a parent ID for the pool, CIDR range descriptor for the allocation(s) to convert, and the pool type
+sub _toPool {
+  my $dbh = shift;
+  my $poolparent = shift;
+  my $convblock = shift;  # May be smaller than the block referenced by $poolparent
+  my $pooltype = shift;
+
+  # there is probably a way to avoid the temporary $foo here
+  my $foo = $dbh->selectall_arrayref("SELECT master_id,parent_id FROM allocations WHERE id = ?", undef, $poolparent);
+  my ($master,$mainparent) = @{$foo->[0]};
+
+  my @retlist;
+
+  my $iptype = $pooltype;
+  $iptype =~ s/[pd]$/i/;
+  my $poolclass = (split //, $iptype)[0];
+
+  my $cidrpool = new NetAddr::IP $convblock;
+
+  my $asth = $dbh->prepare(q{
+      SELECT id, cidr, type, parent_id, city, description, notes, circuitid,
+              createstamp, modifystamp, privdata, custid, vrf, vlan, rdns
+      FROM allocations
+      WHERE cidr <<= ? AND master_id = ?
+      ORDER BY masklen(cidr) DESC
+    });
+  my $inssth = $dbh->prepare(q{
+      INSERT INTO poolips (
+          ip,type,parent_id,available,
+          city,description,notes,circuitid,createstamp,modifystamp,privdata,custid,vrf,vlan,rdns
+          )
+      VALUES (?,?,?,'n',?,?,?,?,?,?,?,?,?,?,?)
+    });
+  my $updsth = $dbh->prepare("UPDATE poolips SET parent_id = ?, type = ? WHERE parent_id = ?");
+  my $delsth = $dbh->prepare("DELETE FROM allocations WHERE id = ?");
+  my $fbdelsth = $dbh->prepare("DELETE FROM freeblocks WHERE parent_id = ?");
+
+  $asth->execute($convblock, $master);
+  my %poolcounter;
+  while (my ($oldid, $oldcidr, $oldtype, $oldparent, @oldalloc) = $asth->fetchrow_array) {
+    if ($oldtype =~ /.[enr]/) {
+      # Convert leaf allocations to block of pool IP assignments
+      my $tmpcidr = new NetAddr::IP $oldcidr;
+      my $newtype = $poolclass.'i';
+      # set up the gateway IP in case we need it
+      my $gw = $cidrpool+1;
+      foreach my $newip ($tmpcidr->split(32)) {
+        my $baseip = $newip->addr;
+        # skip .0 and .255, they are prefectly legitimate but some systems behave
+        # poorly talking to a client using them.
+        next if $baseip =~ /\.(?:0|255)$/;
+        # skip the network, broadcast, and gateway IPs if we're creating a "normal netblock" pool
+        if ($pooltype =~ /d$/) {
+          next if $newip->addr eq $cidrpool->network->addr;
+          next if $newip->addr eq $cidrpool->broadcast->addr;
+          next if $newip->addr eq $gw->addr;
+        }
+        $inssth->execute($newip, $newtype, $poolparent, @oldalloc) if !$poolcounter{"$newip"};
+        $poolcounter{"$newip"}++;
+      }
+    } elsif ($oldalloc[2] =~ /.[dp]/) {
+      # Reparent IPs in an existing pool, and rewrite their type
+      $updsth->execute($poolparent, $poolclass.'i', $oldid);
+    } else {
+      # Containers are mostly "not interesting" in this context since they're
+      # equivalent to the pool allocation on .[dp] types.  Clean up the lingering free block(s).
+      $fbdelsth->execute($oldid);
+    }
+    # Clean up - remove the converted block unless it is the "primary"
+    $delsth->execute($oldid) unless $oldid == $poolparent;
+    # Return the converted blocks, but only the immediate peers, not the entire tree
+    push @retlist, { block => $oldcidr, mtype => $disp_alloctypes{$oldtype} }
+        if $oldparent == $mainparent;
+  }
+  return \@retlist;
+} # end _toPool()